VP SET PRINT INFO

4D v19

VP SET PRINT INFO


VP SET PRINT INFO ( vpAreaName ; printInfo {; sheet} )

引数	型	説明
vpAreaName	テキスト	4D View Pro エリア名
printInfo	オブジェクト	印刷属性を格納したオブジェクト
sheet	倍長整数	シートインデックス(省略時カレントシート)

説明

VP SET PRINT INFO コマンドは、vpAreaName 引数で指定したエリアを印刷する際に使用する属性を定義します。

vpAreaName 引数には、印刷したい4D View Pro エリアの名前を渡します。存在しない名前を渡した場合、エラーが返されます。

printInfo 引数には、様々な印刷属性の定義を格納したオブジェクトを渡します。利用可能な全ての属性の一覧は、4D View Pro 印刷属性を参照してください。

任意のsheet 引数を使用すると、印刷する特定のスプレッドシートを指定することができます(0 から数え始めます)。省略時、デフォルトでカレントのスプレッドシートが使用されます。以下の定数を使用することで、カレントスプレッドシートを明示的に選択することもできます:

定数	型	値	コメント
vk current sheet	倍長整数	-1	4D View Pro エリアのカレントシートを指定します。(デフォルト)

例題

以下のコードを実行すると、4D View Pro エリアをPDF ドキュメントへと印刷します:

C_OBJECT($printInfo)

// 印刷属性オブジェクトを宣言
$printInfo:=New object

// 印刷属性を定義
$printInfo.headerCenter:="&BS.H.I.E.L.D. &A Sales Per Region"
$printInfo.firstPageNumber:=1
$printInfo.footerRight:="page &P of &N"
$printInfo.orientation:=vk print page orientation landscape
$printInfo.centering:=vk print centering horizontal
$printInfo.columnStart:=0
$printInfo.columnEnd:=8
$printInfo.rowStart:=0
$printInfo.rowEnd:=24
$printInfo.showGridLine:=True

// 会社のロゴを追加
$printInfo.headerLeftImage:=logo.png
$printInfo.headerLeft:="&G"

$printInfo.showRowHeader:=vk print visibility hide
$printInfo.showColumnHeader:=vk print visibility hide
$printInfo.fitPagesWide:=1
$printInfo.fitPagesTall:=1

// 印刷情報を設定
VP SET PRINT INFO ("ViewProArea";$printInfo)

// PDF を書き出し
VP EXPORT DOCUMENT("ViewProArea";"Sales2018.pdf";new object("formula";formula(alert("PDF ready!"))))

印刷されたPDF:

参照

4D View Pro 印刷属性
 VP Convert to picture
VP Get print info
VP PRINT