VP SET PRINT INFO

4D v19

VP SET PRINT INFO


VP SET PRINT INFO ( vpAreaName ; infoImpression {; feuille} )

Paramètre	Type	Description
vpAreaName	Texte	Nom de la zone 4D View Pro
infoImpression	Objet	Objet contenant les attributs d'impression
feuille	Entier long	Indice de la feuille (si omis, feuille courante)

Description

La commande VP SET PRINT INFO définit les attributs à utiliser lors de l'impression de vpAreaName.

Passez le nom de la zone 4D View Pro que vous souhaitez imprimer dans vpAreaName. Si vous passez un nom qui n'existe pas, une erreur est retournée.

Vous pouvez passer un objet contenant les définitions de plusieurs attributs d'impression dans le paramètre infoImpression. Pour consulter la liste complète des attributs disponibles, veuillez vous reporter à Attributs d'impression de 4D View Pro.

Dans le paramètre optionnel feuille, vous pouvez désigner une feuille spécifique (la numérotation commence à zéro). Si le paramètre est omis, la feuille courante est utilisée par défaut. Vous pouvez sélectionner explicitement la feuille courante avec la constante suivante :

Constante	Type	Valeur	Comment
vk current sheet	Entier long	-1	Désigne la feuille courante de la zone 4D View Pro (par défaut)

Exemple

Le code suivant imprimera une nouvelle zone 4D View Pro dans un document PDF :

C_OBJECT($printInfo)

//declare l'objet d'attributs d'impression
$printInfo:=Creer objet

//definit les attributs d'impression
$printInfo.headerCenter:="&BS.H.I.E.L.D. &A Sales Per Region"
$printInfo.firstPageNumber:=1
$printInfo.footerRight:="page &P of &N"
$printInfo.orientation:=vk print page orientation landscape
$printInfo.centering:=vk print centering horizontal
$printInfo.columnStart:=0
$printInfo.columnEnd:=8
$printInfo.rowStart:=0
$printInfo.rowEnd:=24
$printInfo.showGridLine:=True

//Ajouter un logo
$printInfo.headerLeftImage:=logo.png
$printInfo.headerLeft:="&G"

$printInfo.showRowHeader:=vk print visibility hide
$printInfo.showColumnHeader:=vk print visibility hide
$printInfo.fitPagesWide:=1
$printInfo.fitPagesTall:=1

//imprimer un document PDF
VP SET PRINT INFO ("ViewProArea";$printInfo)

//exportr le PDF
VP EXPORT DOCUMENT("ViewProArea";"Sales2018.pdf";new object("formula";formula(alert("PDF ready!"))))

Le PDF :

Voir aussi

Attributs d'impression de 4D View Pro
VP Convert to picture
VP Get print info
VP PRINT