VP Find

4D v19

VP Find


VP Find ( objPlage ; searchValue {; searchCondition {; replaceValue}} ) -> Résultat

Paramètre	Type	Description
objPlage	Objet	Objet plage
searchValue	Texte	Valeur de recherche
searchCondition	Objet	Objet contenant la/les condition(s) de recherche
replaceValue	Texte	Valeur de remplacement
Résultat	Objet	Objet plage

Description

La commande VP Find[#descv] recherche le paramètre objPlage pour la searchValue. Des paramètres facultatifs peuvent être utilisés pour affiner la recherche et/ou remplacer les résultats trouvés.

Dans le paramètre objPlage, passez un objet contenant une plage à rechercher.

Le paramètre searchValue vous permet de passer le texte à rechercher dans le objPlage.

Vous pouvez passer le paramètre optionnel searchCondition pour indiquer comment la recherche est effectuée. Les propriétés suivantes sont prises en charge :

Propriété Type Description

afterColumn Entier long Le numéro de la colonne juste avant la colonne de départ de la recherche. Si la plageObj est une plage combinée, le numéro de colonne indiqué doit provenir de la première plage. Valeur par défaut : -1 (début de objPlage)

afterRow Entier long Le numéro de la ligne juste avant la ligne de départ de la recherche. Si rangeObj est une plage combinée, le numéro de ligne indiqué doit provenir de la première plage.Valeur par défaut : -1 (début de objPlage)

all

Booléen

True -Toutes les cellules de objPlage correspondant à searchValue sont retournées
False - (valeur par défaut) Seule la première cellule de objPlage correspondant à searchValue est retournée.

flags

Entier long

Constante	Comment
vk find flag exact match	Indique que tout le contenu de la cellule doit entièrement correspondre à la valeur de recherche.
vk find flag ignore case	Indique que les majuscules et les minuscules sont considérées comme identiques. Ex : "a" est considérée comme identique à "A".
vk find flag none	Indique qu'aucun indicateur de recherche n'est pris en compte (par défaut).
vk find flag use wild cards	Indique que les caractères génériques (,?) peuvent être utilisés dans la chaîne de recherche. Les caractères joker peuvent être utilisés dans n'importe quelle comparaison de chaînes pour correspondre à n'importe quel nombre de caractères. - Pour le caractère zéro ou plusieurs caractères. Par exemple, rechercher "bl*" peut donner comme résultat "bl", "black", "blue", et "blob". ? - Pour un seul caractère. Par exemple, rechercher "h?t" peut donner comme résultat "hot", "hat", et "hit".

Ces marqueurs peuvent être combinés. Par exemple :

$search.flags:=vk find flag use wild cards+vk find flag ignore case

order

Entier long

Constante	Comment
vk find order by columns	Indique que la recherche est effectuée par colonnes. Chaque ligne d'une colonne est recherchée avant que la recherche ne passe à la colonne suivante.
vk find order by rows	Indique que la recherche est effectuée par lignes. Chaque colonne d'une ligne est recherchée avant que la recherche passe à la ligne suivante (par défaut).

target

Entier long

Constante	Comment
vk find target formula	Indique que la recherche est effectuée dans la formule de la cellule.
vk find target tag	Indique que la recherche est effectuée dans la balise de la cellule.
vk find target text	Indique que la recherche est effectuée dans le texte de la cellule (par défaut).

Ces marqueurs peuvent être combinés. Par exemple :

$search.target:=vk find target formula+vk find target text

Dans le paramètre optionnel replaceValue, vous pouvez passer du texte pour remplacer toute instance du texte dans la searchValue trouvée dans objPlage.

Objet retourné

La fonction retourne un objet de plage décrivant chaque valeur de recherche trouvée ou remplacée. Un objet de plage vide est retourné si aucun résultat n'est trouvé.

Exemple 1

Pour trouver la première cellule contenant le mot "Total" :

 var $range;$result : Object

 

 $range:=VP All("ViewProArea")

 

 $result:=VP Find($range;"Total")

Exemple 2

Pour trouver "Total" et le remplacer par "Grand Total":

 var $range;$condition;$result : Object

 

 $range:=VP All("ViewProArea")

 

 $condition:=Creer objet

 $condition.target:=vk find target text

 $condition.all:=True //Rechercher le document entier

 $condition.flags:=vk find flag exact match

 

  // Remplacer les cellules contenant uniquement 'Total' dans la feuille courante par "Grand Total"

 $result:=VP Find($range;"Total";$condition;"Grand Total")

 

  // Rechercher un objet de plage vide

 Si($result.ranges.length=0)

    ALERTE("Aucun résultat trouvé")

 Sinon

    ALERTE($result.ranges.length+" résultats trouvés")

 Fin de si