VP SET SHEET OPTIONS

4D v19


VP SET SHEET OPTIONS ( vpAreaName ; optionsFeuille {; feuille} )

Paramètre	Type	Description
vpAreaName	Chaîne	Nom de la zone 4D View Pro
optionsFeuille	Objet	Option(s) de la feuille à définir
feuille	Entier long	Indice de la feuille (feuille courante si omis)

Description

La commande VP SET SHEET OPTIONS permet de définir plusieurs options appliquées à une feuille de la zonevpAreaName.

Passez le nom de la zone 4D View Pro dans vpAreaName. Si vous passez un nom qui n'existe pas, une erreur est retournée.

Passez un objet contenant les défintions des options à définir dans le paramètre optionsFeuille. Pour visualiser la liste complète des options disponibles, veuillez vous reporter à Options feuille 4D View Pro.

Dans le paramètre optionnel feuille, vous pouvez indiquer une feuille de calcul spécifiique (la numérotation commence à partir de zéro). S'il est omis, la feuille courante est utilisée par défaut.

Constante	Valeur	Comment
vk current sheet	-1	Désigne la feuille courante de la zone 4D View Pro (par défaut)

Exemple 1

Vous souhaitez protéger toutes les cellules de la plage C5:D10 :

  // Activer la protection sur la feuille courante

 C_OBJET($options)

 $options:=Creer objet

 $options.isProtected:=Vrai

 VP SET SHEET OPTIONS("ViewProArea";$options)

  // marquer les cellules C5:D10 comme 'déverrouillées'

 VP SET CELL STYLE(VP Cells("ViewProArea";2;4;2;6);Creer objet("locked";Faux))

Exemple 2

Vous souhaitez protéger votre document pendant que vos utilisateurs redimensionnent les lignes et colonnes :

 C_OBJET($options)

 $options:=Creer objet

  // Activer la protection

 $options.isProtected:=Vrai

 $options.protectionOptions:=Creer objet

  // Permet à l'utilisateur de redimensionner les lignes

 $options.protectionOptions.allowResizeRows=Vrai;

  //  Permet à l'utilisateur de redimensionner les colonnes

 $options.protectionOptions.allowResizeColumns=Vrai;

  // Appliquer la protection à la feuille courante

 VP SET SHEET OPTIONS("ViewProArea";$options)

Exemple 3

Vous souhaitez personnaliser la couleur des onglets, des lignes figées, du quadrillage, du fond de la sélection et de la bordure de la sélection :

 C_OBJET($options)

 $options:=Creer objet

  // Personnaliser la couleur de l'onglet de la feuille 1

 $options.sheetTabColor:="Black"

 $options.gridline:=Creer objet("color";"Purple")

 $options.selectionBackColor:="rgb(255,128,0,0.4)"

 $options.selectionBorderColor:="Yellow"

 $options.frozenlineColor:="Gold"

 VP SET SHEET OPTIONS("ViewProArea";$options;0)

 

  // Personnaliser la couleur de l'onglet de la feuille 2

 $options.sheetTabColor:="red"

 VP SET SHEET OPTIONS("ViewProArea";$options;1)

 

  // Personnaliser la couleur de l'onglet de la feuille 3

 $options.sheetTabColor:="blue"

 VP SET SHEET OPTIONS("ViewProArea";$options;2)

Resultat :

Exemple 4

Vous souhaitez masquer le quadrillage et les en-têtes des lignes et colonnes.

 C_OBJET($options)

 $options:=Creer objet

 $options.gridline:=Creer objet()

 $options.gridline.showVerticalGridline:=Faux

 $options.gridline.showHorizontalGridline:=Faux

 $options.rowHeaderVisible:=Faux

 $options.colHeaderVisible:=Faux

 VP SET SHEET OPTIONS("ViewProArea";$options)

Le résultat est le suivant :

Voir aussi

Options feuille 4D View Pro
VP Get sheet options