VP SET SHEET OPTIONS

4D v19


VP SET SHEET OPTIONS ( vpAreaName ; sheetOptions {; sheet} )

引数	型	説明
vpAreaName	文字	4D View Pro エリア名
sheetOptions	オブジェクト	設定するシートのオプション
sheet	倍長整数	シートのインデックス(省略時はカレントシート)

説明

VP SET SHEET OPTIONS コマンドは、vpAreaName 引数で名前を指定したView Pro エリアの、様々なシートオプションを定義することができます。

vpAreaName には4D View Pro エリアの名前を渡します。存在しない名前を渡した場合、エラーが返されます。

sheetOptions 引数には、設定するオプションの定義を格納したオブジェクトを渡します。利用可能なすべてのオプションについては、4D View Pro シートオプションを参照してください。

任意のsheet 引数を使用すると、特定のスプレッドシートを指定することができます(0 から数え始めます)。省略時、カレントのスプレッドシートがデフォルトで使用されます。以下の定数を使用することで、カレントのスプレッドシートを明示的に選択することもできます:

定数	値	コメント
vk current sheet	-1	4D View Pro エリアのカレントシートを指定します。(デフォルト)

例題 1

C5:D10 のレンジを除いて、全てのセルを保護したい場合を考えます:

  // カレントシート上でセルの保護を有効化する

 C_OBJECT($options)

 $options:=New object

 $options.isProtected:=True

 VP SET SHEET OPTIONS("ViewProArea";$options)

  // C5:D10 を 'unlocked' に設定する

 VP SET CELL STYLE(VP Cells("ViewProArea";2;4;2;6);New object("locked";False))

例題 2

ドキュメントを保護しつつも、ユーザーが行とカラムをリサイズできるようにしたい場合を考えます:

 C_OBJECT($options)

 $options:=New object

  // 保護を有効化

 $options.isProtected:=True

 $options.protectionOptions:=New object

  // ユーザーに行のリサイズを許可

 $options.protectionOptions.allowResizeRows=True;

  // ユーザーにカラムのリサイズを許可

 $options.protectionOptions.allowResizeColumns=True;

  // カレントシートに上記の設定での保護を適用

 VP SET SHEET OPTIONS("ViewProArea";$options)

例題 3

シートのタブ、固定化された線、枠線、選択範囲の背景と選択範囲の境界線のカラーをカスタマイズしたい場合を考えます:

 C_OBJECT($options)

 $options:=New object

  // Sheet1 のタブのカラーをカスタマイズ

 $options.sheetTabColor:="Black"

 $options.gridline:=New object("color";"Purple")

 $options.selectionBackColor:="rgb(255,128,0,0.4)"

 $options.selectionBorderColor:="Yellow"

 $options.frozenlineColor:="Gold"

 VP SET SHEET OPTIONS("ViewProArea";$options;0)

 

  // Sheet 2 タブのカラーをカスタマイズ

 $options.sheetTabColor:="red"

 VP SET SHEET OPTIONS("ViewProArea";$options;1)

 

  // Sheet 3 タブのカラーをカスタマイズ

 $options.sheetTabColor:="blue"

 VP SET SHEET OPTIONS("ViewProArea";$options;2)

実行した結果は以下のようになります:

例題 4

枠線と、行ヘッダー/カラムヘッダーを非表示にしたい場合を考えます:

 C_OBJECT($options)

 $options:=New object

 $options.gridline:=New object()

 $options.gridline.showVerticalGridline:=False

 $options.gridline.showHorizontalGridline:=False

 $options.rowHeaderVisible:=False

 $options.colHeaderVisible:=False

 VP SET SHEET OPTIONS("ViewProArea";$options)

実行した結果は以下のようになります:

参照

4D View Pro シートオプション
 VP Get sheet options