VP Find

4D v19

VP Find


VP Find ( objRango ; valorBuscar {; condicionBuscar {; valorReemplazo}} ) -> Resultado

Parámetro	Tipo	Descripción
objRango	Objeto	Objeto rango
valorBuscar	Texto	Valor a buscar
condicionBuscar	Objeto	Objeto que contiene condición(es) de búsqueda
valorReemplazo	Texto	Valor de reemplazo
Resultado	Objeto	Objeto rango

Descripción

El comando VP Find busca el objRango para el valor valorBuscar. Los parámetros opcionales se pueden utilizar para refinar la búsqueda y/o reemplazar los resultados encontrados.

En el parámetro objRango, pase un objeto que contenga un rango a buscar.

El parámetro valorBuscar le permite pasar el texto a buscar dentro del objRango.

Puede pasar el parámetro opcional condicionBuscar para especificar cómo se realiza la búsqueda. Se soportan las siguientes propiedades:

Propiedad Tipo Descripción

afterColumn Entero largo El número de la columna justo antes de la columna de inicio de la búsqueda. Si objRango es un rango combinado, el número de columna dado debe ser del primer rango. Valor predeterminado: -1 (inicio del objRango)

afterRow Entero largo El número de la fila justo antes de la fila de inicio de la búsqueda. Si objRango es un rango combinado, el número de fila dado debe ser del primer rango. Valor predeterminado: -1 (inicio del objRango)

all

Booleano

True - se devuelven todas las celdas en objRango correspondientes a valorBuscar
False - (valor predeterminado) Solo se devuelve la primera celda en objRango correspondiente a valorBuscar

flags

Entero largo

Constante	Comentario
vk find flag exact match	Especifica que todo el contenido de la celda debe coincidir completamente con el valor de búsqueda.
vk find flag ignore case	Especifica que las mayúsculas y las minúsculas se consideran iguales. Por ejemplo: "a" es lo mismo que "A".
vk find flag none	Especifica que no se consideran banderas de búsqueda. (por defecto)
vk find flag use wild cards	Especifica que se pueden utilizar caracteres comodín (, ?) en la cadena de búsqueda. Los caracteres comodín se pueden utilizar en cualquier comparación de cadenas para coincidir con cualquier número de caracteres. - Para cero o varios caracteres. Por ejemplo, al buscar "bl *" se pueden encontrar "bl", "black", "blue" y "blob". ? - Para un solo caracter. Por ejemplo, al buscar "h?t" se pueden encontrar "hot", "hat" y "hit".

Estas banderas se pueden combinar. Por ejemplo:

$search.flags:=vk find flag use wild cards+vk find flag ignore case

order

Entero largo

Constante	Comentario
vk find order by columns	Especifica que la búsqueda se realiza por columnas. Cada fila de una columna se busca antes de que la búsqueda continúe en la siguiente columna.
vk find order by rows	Especifica que la búsqueda se realiza por filas. Cada columna de una fila se busca antes de que la búsqueda continúe en la fila siguiente. (por defecto)

target

Entero largo

Constante	Comentario
vk find target formula	Especifica que la búsqueda se realiza en la fórmula de la celda.
vk find target tag	Especifica que la búsqueda se realiza en la etiqueta de la celda.
vk find target text	Especifica que la búsqueda se realiza en el texto de la celda. (por defecto)

Estas banderas se pueden combinar. Por ejemplo:

$search.target:=vk find target formula+vk find target text

En el parámetro opcional valorReemplazo, puede pasar texto para que ocupe el lugar de toda instancia del texto en valorBuscar encontrada en el objRango.

Objeto devuelto

La función devuelve un objeto rango que describe cada valor de búsqueda que se encontró o reemplazó. Se devuelve un objeto rango vacío si no se encuentran resultados.

Ejemplo 1

Para encontrar la primera celda que contiene la palabra "Total":

 var $range;$result : Object

 

 $range:=VP All("ViewProArea")

 

 $result:=VP Find($range;"Total")

Ejemplo 2

Para encontrar "Total" y reemplazarlo por "Grand Total":

 var $range;$condition;$result : Object

 

 $range:=VP All("ViewProArea")

 

 $condition:=New object

 $condition.target:=vk find target text

 $condition.all:=True //Buscar en todo el documento

 $condition.flags:=vk find flag exact match

 

  // Reemplazar las celdas que contienen sólo 'Total' en la hoja actual por "Grand Total"

 $result:=VP Find($range;"Total";$condition;"Grand Total")

 

  // Compruebe si hay un objeto rang vacío

 If($result.ranges.length=0)

    ALERT("No se encontró ningún resultado")

 Else

    ALERT($result.ranges.length+" resultados encontrados")

 End if