VP EXPORT DOCUMENT

4D v19

VP EXPORT DOCUMENT


VP EXPORT DOCUMENT ( vpAreaName ; rutaArchivo {; paramObj} )

Parámetro	Tipo	Descripción
vpAreaName	Texto	Nombre del área 4D View Pro en el formulario
rutaArchivo	Texto	Ruta de acceso del documento
paramObj	Objeto	Opciones de exportación

Descripción

El comando VP EXPORT DOCUMENT exporta el objeto 4D View Pro adjunto al área 4D View Pro vpAreaName a un documento en disco de acuerdo con los parámetros rutaArchivo.y paramObj.

En vpAreaName, pase la propiedad nombre del objeto de área en el formulario 4D. Si pasa un nombre no válido, se devuelve un error.

En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.

En rutaArchivo, pase la ruta de destino y el nombre del documento a exportar. Puede especificar el formato del documento incluyendo su extensión, 4D View Pro (".4VP") o Microsoft Excel (".xlsx"), o PDF (".pdf") después del nombre del documento. Si sólo pasa el nombre del documento, se guardará en el mismo nivel que el archivo de estructura 4D con la extensión por defecto ".4vp".

Nota: al exportar un documento 4D View Pro a un archivo con formato Microsoft Excel, algunas configuraciones pueden perderse. Por ejemplo, los métodos 4D y las fórmulas no son soportadas por Excel. Puede verificar otras configuraciones con esta lista de GrapeCity.

El parámetro opcional paramObj le permite definir múltiples propiedades para el objeto 4D View Pro exportado, así como también ejecutar un método de devolución de llamada cuando la exportación se haya completado.

Propiedad

Tipo

Descripción

format

texto

(opcional) Cuando está presente, designa el formato de archivo exportado: ".4vp" (por defecto) o ".xlsx", o ".pdf". Puede pasar una constante del tema Constantes 4D View Pro en el parámetro formato. En este caso, 4D agrega la extensión apropiada al nombre del archivo si es necesario.

Se soportan los siguientes formatos:

Constante	Valor	Comentario
vk 4D View Pro format	.4VP	Formato 4D View Pro (formato por defecto)
vk MS Excel format	.xlsx	Formato Microsoft Excel
vk pdf format	.pdf	Formato PDF

Si el formato especificado no corresponde con la extensión en rutaArchivo, se agregará al final de rutaArchivo. Si no se especifica un formato y no se ofrece ninguna extensión en rutaArchivo, se utiliza el formato de archivo predeterminado.

password

texto

Microsoft Excel únicamente (opcional) - Contraseña utilizada para proteger el documento MS Excel

formula

objeto

Un método de retrollamada que se lanzará cuando se complete la exportación. El uso de un método de retrollamada es necesario cuando la exportación es asíncrona (como en el caso de los formatos PDF y Excel) si se necesita que se ejecute algún código después de la exportación. . El método de retrollamada se debe utilizar con el comando Formula. Ver abajo para más información.

valuesOnly

booleano

Especifica que solo se exportarán los valores de las fórmulas (si los hay).

includeFormatInfo

booleano

True para incluir información de formato, de lo contrario false (el valor predeterminado es true). La información de formato es útil en algunos casos, por ejemplo para exportar a SVG. Por otro lado, definir esta propiedad como false permite reducir el tiempo de exportación.

sheetIndex

número

PDF solamente (opcional) - Índice de hoja para exportar (a partir de 0). -2 = todas las hojas visibles (predeterminado), -1 = hoja actual solamente

pdfOptions

objeto

PDF únicamente (opcional) - Opciones para la exportación pdf

Propiedad	Tipo	Descripción
creator	texto	nombre de la aplicación que creó el documento original desde el cual se convirtió.
título	texto	título del documento.
autor	texto	nombre de la persona que creó ese documento.
keywords	texto	palabras claves asociadas con el documento.
asunto	texto	asunto del documento.

any

Toda propiedad personalizada que estará disponible a través del parámetro $3 en el método de retrollamada.

Notas sobre el formato de Excel:
- Al exportar un documento 4D View Pro a un archivo con formato de Microsoft Excel, se pueden perder algunas configuraciones. Por ejemplo, Excel no admite métodos y fórmulas 4D. Puede verificar otras configuraciones con esta lista de GrapeCity.
- La exportación en este formato se ejecuta de forma asincrónica, utilice la propiedad fórmula del paramObjet para que el código se ejecute después de la exportación.

Notas sobre el formato PDF:
- Al exportar un documento 4D View Pro en PDF, las fuentes utilizadas en el documento se integran automáticamente en el archivo PDF. Solo se pueden integrar fuentes OpenType (archivos .OTF o .TTF) que tengan un mapa Unicode. Si no se encuentra un archivo de fuente válido para una fuente, se utiliza una fuente predeterminada.
- La exportación en este formato se ejecuta de forma asincrónica, utilice la propiedad fórmula del paramObjet para el código que se ejecutará después de la exportación.

Una vez que finaliza la operación de exportación, VP EXPORT DOCUMENT activa automáticamente la ejecución del método establecido en la propiedad formula del paramObj, si se usa.

Pasar un método retrollamada (fórmula)

Al incluir el parámetro opcional paramObj, el comando VP EXPORT DOCUMENT le permite usar el comando Formula para llamar a un método 4D que se ejecutará una vez que se haya completado la exportación. El método de retrollamada recibirá los siguientes valores en las variables locales:

Variable		Tipo	Descripción
$1		texto	Nombre del objeto 4D View Pro
$2		texto	Ruta de acceso del objeto 4D View Pro exportado
$3		objeto	Referencia al paramObj del comando
$4		objeto	Objeto devuelto por el método con un mensaje de estado
	.success	booleano	True si se exporta con éxito, de lo contrario es False.
	.errorCode	entero	Código de error. Puede ser devuelto por 4D o JavaScript.
	.errorMessage	texto	Mensaje de error. Puede ser devuelto por 4D o JavaScript.

Ejemplo 1

Usted desea exportar el contenido del área "VPArea" a un documento 4D View Pro en el disco:

 C_TEXT($docPath)

 

 $docPath:="C:\\Bases\\ViewProDocs\\MyExport.4VP"

 VP EXPORT DOCUMENT("VPArea";$docPath)

  //MyExport.4VP es guardado en el disco

Ejemplo 2

Usted desea exportar la hoja actual en PDF:

 C_OBJECT($params)

 $params:=New object

 $params.format:=vk pdf format

 $params.sheetIndex:=-1

 $params.pdfOptions:=New object("title";"Annual Report";"author";Current user)

 VP EXPORT DOCUMENT("VPArea";"report.pdf";$params)

Ejemplo 3

Usted desea exportar un documento de 4D View Pro en formato ".xlsx" y llamar a un método que abrirá Microsoft Excel con el documento abierto una vez que se haya completado la exportación:

 $params:=New object

 $params.formula:=Formula(AfterExport)

 $params.format:=vk MS Excel format //".xlsx"

 $params.valuesOnly:=True

 

 VP EXPORT DOCUMENT("ViewProArea";"c:\\tmp\\convertedfile";$params)

Método AfterExport:

 C_TEXT($1;$2)

 C_OBJECT($3;$4)

 $areaName:=$1

 $filePath:=$2

 $params:=$3

 $status:=$4

 

 If($status.success=False)

    ALERT($status.errorMessage)

 Else

    LAUNCH EXTERNAL PROCESS("C:\\Program Files\\Microsoft Office\\Office15\\excel "+$filePath)

 End if

Ver también

VP Export to object
VP Convert to picture
VP IMPORT DOCUMENT
VP PRINT