WP Table append row

4D v20

WP Table append row


WP Table append row ( refTab ; valor {; valor2 ; ... ; valorN} ) -> Resultado

Parâmetro	Tipo	Descrição
refTab	Objeto	objeto referência Tabela
valor	Texto, Número, Hora, Data, Imagem	Valores a estabelecer na fila
Resultado	Objeto	Objeto faixa Fila

Descrição

O comando WP Table append row agrega uma fila à tabela refTabela, a preenche com valor(es) e devolve o objeto de faixa de fila correspondente.

O comando agrega tantas celulas na fila como há valores no parâmetro valor. Pode passar qualquer número de valores de diferentes tipos; O alinhamento de celula predeterminada dependerá do tipo de valor:

texto: alinhado a esquerda
imágens: centrado
outro tipo (números, data e hora): alinhado a direita

Nota: os valores de tipo de array não são suportados.

O comando devolve a nova fila como um objeto de faixa de fila.

Exemplo 1

Se deseja criar uma tabela vazia e agregar várias filas de diferentes tamanhos. Pode escrever:

 C_OBJECT($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3)

 $wpRange:=WP Text range(WParea;wk start text;wk end text)

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18;"New!")

Exemplo 2

Em uma aplicação de fatura, se quiser criar uma tabela preenchida automaticamente com as lihas de fatura relacionadas:

 C_OBJECT($wpTable;$wpRange)

 

 $wpRange:=WP Text range(4DWPArea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append) //cria a tabela

 

  // adicionar a fila de cabeçalho

 $row:=WP Table append row($wpTable;"Name";"Quantity";"Unit Price";"Discount Rate";"Total")

 WP SET ATTRIBUTES($row;wk font bold;wk true;wk text align;wk center)

 

  //simplesmente aplicar à seleção

 APPLY TO SELECTION([INVOICE_LINES];WP Table append row($wpTable;[INVOICE_LINES]ProductName;[INVOICE_LINES]Quantity;[INVOICE_LINES]ProductUnitPrice;[INVOICE_LINES]DiscountRate;[INVOICE_LINES]Total))

 

  //adicionar uma fila de rodapé

 $row:=WP Table append row($wpTable;"Total:";Sum([INVOICE_LINES]Quantity);"";"";Sum([INVOICE_LINES]Total))

 

  //formatar a tabela

 $range:=WP Table get columns($wpTable;1;5)

 WP SET ATTRIBUTES($range;wk width;"80pt")

 WP SET ATTRIBUTES($wpTable;wk font size;10)

Ver também

WP Insert table
WP Table get rows