WP Table append row

Home

4D v20

WP Table append row


WP Table append row ( TabelleRef ; Wert {; Wert2 ; ... ; WertN} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
TabelleRef	Objekt	Objekt Tabellenreferenz
Wert	Text, Zahl, Zeit, Datum, Bild	Zu setzender Wert/Werte in der Zeile
Funktionsergebnis	Objekt	Objekt Zeilenausschnitt

Beschreibung

Die Funktion WP Table append row fügt an die Tabelle TabelleRef eine Zeile an, füllt sie mit Wert und gibt das neue Objekt Zeilenausschnitt zurück.

Diese Funktion fügt die Anzahl Zellen in der Zeile hinzu, die im Parameter Wert definiert wurde. Sie können eine beliebige Anzahl Werte unterschiedlichen Typs übergeben; die standardmäßige Zellenausrichtung richtet sich nach dem jeweiligen Typ:

Text ist links ausgerichtet
Bilder sind zentriert
Andere Typen (Zahlen, Datum und Zeit) sind rechts ausgerichtet

Hinweis: Werte vom Typ Array werden nicht unterstützt.

Die Funktion gibt die neue Zeile als Objekt Zellenausschnitt zurück.

Beispiel 1

Eine leere Tabelle erstellen und mehrere Zeilen mit unterschiedlicher Größe anhängen:

 C_OBJECT($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3)

 $wpRange:=WP Text range(WParea;wk start text;wk end text)

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18;"New!")

Beispiel 2

In einer Anwendung Rechnungen eine Tabelle anlegen, die automatisch mit verknüpften Rechnungszeilen gefüllt wird:

 C_OBJECT($wpTable;$wpRange)

 

 $wpRange:=WP Text range(4DWPArea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append) //Tabelle anlegen

 

  // Eine Kopfteilzeile hinzufügen

 $row:=WP Table append row($wpTable;"Name";"Quantity";"Unit Price";"Discount Rate";"Total")

 WP SET ATTRIBUTES($row;wk font bold;wk true;wk text align;wk center)

 

  //Einfach auf die Auswahl anwenden

 APPLY TO SELECTION([INVOICE_LINES];WP Table append row($wpTable;[INVOICE_LINES]ProductName;[INVOICE_LINES]Quantity;[INVOICE_LINES]ProductUnitPrice;[INVOICE_LINES]DiscountRate;[INVOICE_LINES]Total))

 

  //Eine Fußteilzeile hinzufügen

 $row:=WP Table append row($wpTable;"Total:";Sum([INVOICE_LINES]Quantity);"";"";Sum([INVOICE_LINES]Total))

 

  //Tabelle formatieren

 $range:=WP Table get columns($wpTable;1;5)

 WP SET ATTRIBUTES($range;wk width;"80pt")

 WP SET ATTRIBUTES($wpTable;wk font size;10)

Siehe auch

WP Insert table
WP Table get rows