WP New text box

Home

4D v20

WP New text box


WP New text box ( wpDoc ; pageNum ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
wpDoc	Objekt	4D Write Pro document
pageNum	Zahl	Page number where to anchor the text box
Funktionsergebnis	Objekt	Text box object

Beschreibung

Der Befehl WP New text box erstellt ein neues Textfeld-Objekt in der Seite pageNum von wpDoc und gibt es zurück.

Hinweis: Weitere Informationen zu Textfeldern finden Sie im Absatz Umgang mit Textfeldern.

Im Parameter wpDoc übergeben Sie ein 4D Write Pro Dokument.

Übergeben Sie in pageNum die Seitenzahl, auf der das Textfeld verankert werden soll. Ist pageNum < 0, wird die Seitennummer 1 verwendet (es wird kein Fehler erzeugt).

Der Befehl erstellt ein neues Textfeld-Element mit den folgenden Standardattributen:

Breite = 8 cm,
Höhe = auto,
fester schwarzer Rand 1 pt,
Einrückung = 4 pt,
Rand = 0 pt,
Hintergrundfarbe = weiß,
id = "textBoxN", wobei N eine Zahl ist,
vor dem Hauptteil an der linken oberen Ecke des Seitenrechtecks verankert (wie ein verankertes Bild kann ein Textfeld im eingebetteten Modus oder in einem Abschnitt, in allen Abschnitten oder in einem Unterabschnitt im Seitenmodus sowie in der Hintergrund- oder Vordergrundebene verankert werden).

Im Abschnitt 4D Write Pro Attribute finden Sie eine detaillierte Beschreibung dieser Attribute.

Das neue Textfeld wird nur auf der Seite pageNum gerendert, d.h. es wird möglicherweise nicht gerendert, wenn:

es keine Seite mit der übergebenen Seitennummer gibt
der aktuelle Anzeigemodus ist eingebettet oder Entwurf

Das Textfeld existiert jedoch weiterhin und gehört zum Dokument, auch wenn es nicht gerendert wird.

Beispiel 1

Sie möchten ein leeres Standard-Textfeld erstellen:

$textBox:=WP New text box(WParea;1)

Ergebnis:

Beispiel 2

Sie möchten in einer Briefvorlage ein Textfeld einfügen, um die Adresse des Empfängers (die im Kontext gespeichert ist) anzuzeigen:

  // #1 Erstellen Sie das Textfeld

 $textBox:=WP New text box(WParea;1)

 

  // #2 einige Textfeld-Attribute definieren

 WP SET ATTRIBUTES($textBox;wk id;"AddressArea")

 WP SET ATTRIBUTES($textBox;wk anchor origin;wk paper box)

 WP SET ATTRIBUTES($textBox;wk anchor horizontal align;wk left;wk vertical align;wk top)

 WP SET ATTRIBUTES($textBox;wk anchor horizontal offset;$form.offsetX.values[$form.offsetX.index])

 WP SET ATTRIBUTES($textBox;wk anchor vertical offset;$form.offsetY.values[$form.offsetY.index])

 WP SET ATTRIBUTES($textBox;wk width;$form.width.values[$form.width.index])

 WP SET ATTRIBUTES($textBox;wk height;$form.height.values[$form.height.index])

 WP SET ATTRIBUTES($textBox;wk padding;$form.padding.values[$form.padding.index]) // innerhalb der Margen

 WP SET ATTRIBUTES($textBox;wk border style;wk dashed;wk border color;"Blue";wk border width;"1pt";wk border radius;"10pt")

 WP SET ATTRIBUTES($textBox;wk vertical align;wk center)

 

  // #3 Definieren Sie die Formeln innerhalb des Textfeldes

 WP INSERT FORMULA($textBox;Formula(This.data.fullName);wk append)

 WP INSERT BREAK($textBox;wk paragraph break;wk append)

 WP INSERT FORMULA($textBox;Formula(This.data.fullAddress);wk append)

 

  // #4: Den Inhalt des Textfeldes gestalten

 WP SET ATTRIBUTES($textBox;wk font;"Arial";wk font bold;wk true;wk font size;"18pt")

Ergebnis:

Siehe auch

WP DELETE TEXT BOX