Form

Home

4D v20 R7

Form


Form -> Funktionsergebnis

Parameter	Typ	Beschreibung
Funktionsergebnis	Objekt	Dem aktuellen Formular zugeordnete Formulardaten

Beschreibung

Die Funktion Form gibt das dem aktuellen Formular zugeordnete Objekt zurück, falls vorhanden. 4D weist dem aktuellen Formular automatisch ein Objekt zu, wenn:

das aktuelle Formular über den Befehl DIALOG angezeigt wird
das aktuelle Formular ein Unterformular ist
ein Tabellenformular aktuell auf dem Bildschirm angezeigt wird

Formular über DIALOG

Wird das aktuelle Formular über den Befehl DIALOG aufgerufen, gibt Form entweder ein leeres Objekt oder das Objekt FormularData zurück, wenn es als Parameter an DIALOG übergeben wurde.

Unterformular

Ist das aktuelle Formular ein Unterformular, richtet sich das zurückgegebene Objekt nach der Variablen des übergeordneten Container:

Ist die Variable als Objekt (_O_C_OBJECT) typisiert, gibt Form den Wert dieser Variablen zurück.
Dann wird über Form dasselbe Objekt zurückgegeben wie über die Anweisung:
(OBJECT Get pointer(Object subform container))->

Ist die Variable nicht als ein Objekt typisiert, gibt Form im Unterformularkontext ein leeres Objekt zurück.

Weitere Informationen dazu finden Sie im Abschnitt Unterformulare als Seite.

Form gibt das Objekt zurück, das dem auf dem Bildschirm angezeigten Tabellenformular zugewiesen ist. Bei einem Eingabeformular, das über ein Ausgabeformular angezeigt wird, z.B. nach Doppelklick auf einen Datensatz, enthält das zurückgegebene Objekt die Eigenschaft:

Eigenschaft	Typ	Beschreibung
parentForm	object	Form Objekt des übergeordneten Ausgabeformulars

Beispiel

In einen Eingabeformular zu einer Person lässt sich über die Schaltfläche "Check Children" ein Dialog öffnen, um Name und Alter ihrer Kinder zu überprüfen/ändern:

Hinweis: Das Objektfeld "Children" dient nur dazu, um seine Struktur für dieses Beispiel anzuzeigen.

Im Fenster zur Überprüfing haben Sie den Form Objekteigenschaften Variablen zugewiesen:

Der Code für die Schaltfläche "Check Children" lautet:

 C_LONGINT($win;$n;$i)

 C_BOOLEAN($save)

 ARRAY OBJECT($children;0)

 OB GET ARRAY([Person]Children;"children";$children) //die  Collection children erhalten

 $save:=False //die Variable save initialisieren

 

 $n:=Size of array($children)

 If($n>0)

    $win:=Open form window("Edit_Children";Movable form dialog box)

    SET WINDOW TITLE("Check children for "+[Person]Name)

    For($i;1;$n) //für jedes Kind

       DIALOG("Edit_Children";$children{$i}) //den mit Werten gefüllten Dialog anzeigen

       If(OK=1) //der Benutzer hat auf OK geklickt

          $save:=True

       End if

    End for

    If($save=True)

       [Person]Children:=[Person]Children //Update des Objektfeldes erzwingen

    End if

    CLOSE WINDOW($win)

 Else

    ALERT("No child to check.")

 End if

Hinweis: Für dieses Beispiel muss die Objektnotation in der Anwendung aktiviert sein (siehe Seite Kompatibilität).

Das Formular zeigt Information zu jedem Kind an:

Werden die Werte bearbeitet und auf die Schaltfläche OK geklickt, wird das Feld aktualisiert (der übergeordnete Datensatz muss anschließend gesichert werden).

Siehe auch

DIALOG