OBJECT SET HELP TIP

Home

4D v20 R7

OBJECT SET HELP TIP


OBJECT SET HELP TIP ( {* ;} Objekt ; HilfeTipp )

Parameter	Typ	Beschreibung
*	Operator	Mit Stern: Objekt ist ein Objektname (String), Ohne Stern: Objekt ist eine Variable
Objekt	Formularobjekt	Objektname (mit ) oder Variable (ohne )
HilfeTipp	Text	Inhalt der Hilfemeldung

Beschreibung

Der Befehl OBJECT SET HELP TIP setzt oder ändert dynamisch den Hilfetipp für das bzw. die Objekte, angegeben in den Parametern Objekt und * für den aktuellen Prozess.

Übergeben Sie den optionalen Parameter *, ist Objekt ein Objektname (String). Ohne diesen Parameter ist Objekt eine Variable. In diesem Fall übergeben Sie eine Variablenreferenz anstelle eines String.

Im Parameter HilfeTipp übergeben Sie eine Zeichenkette für den Inhalt der Meldung. Übergeben Sie einen leeren String "", wird der Hilfetipp entfernt.

Beim Ausführen des Formulars erscheinen Hilfemeldungen als Hilfetipps, wenn der Cursor über das Feld oder Objekt geht. Die verzögerte Anzeige und maximale Dauer der Anzeige von Hilfemeldungen lässt sich über die Selektoren Tips delay und Tips duration des Befehls SET DATABASE PARAMETER steuern.

Mit dem Befehl OBJECT SET HELP TIP lassen sich Hilfetipps dynamisch steuern: Er schließt den angezeigten Hilftetipp, öffnet an der Mausposition einen neuen Tipp und startet den Zähler Tips duration neu.

Hinweise:

Der Inhalt von Hilfetipps lässt sich auch im Formulareditor (siehe Eingabekontrollen) und im Struktureditor (siehe Feldeigenschaften) des Designmodus setzen.
Mit dem Selektor Tips enabled des Befehls SET DATABASE PARAMETER lassen sich Hilfetipps global deaktivieren.

Beispiel 1

In diesem Formular erscheint ein Hilfetipp und ändert sich automatisch, wenn die Maus über verschiedene Teile der Bildschaltfläche geht:

  //Objektmethode "myFlag"

 

 C_REAL($x;$y;oldX;oldY)

 C_REAL($left;$right;$top;$bottom)

 C_LONGINT($b)

 C_TEXT($tip)

 C_TEXT(oldTip)

 C_BOOLEAN($doRefresh)

 

 Case of

    :(FORM Event=On Load)

       oldTip:=""

       SET DATABASE PARAMETER(Tips enabled;1) //Aktivierung von Tipps sicherstellen

       SET DATABASE PARAMETER(Tips delay;0) // Tipp wird unmittelbar bei Mausstopp angezeigt

       SET DATABASE PARAMETER(Tips duration;60*10) // max. Anzeigedauer 10 Sekunden

    :(FORM Event=On Mouse Move)

       GET MOUSE($x;$y;$b)

       OBJECT GET COORDINATES(*;"myFlag";$left;$top;$right;$bottom)

       $x:=$x-$left

       $y:=$y-$top

       Case of //jeder Teil der Flagge ist 76 Pixel

          :($x<76)

             $tip:="Green color"

          :($x<152)

             $tip:="White color"

          Else

             $tip:="Orange color"

       End case

 

       $doRefresh:=($tip#oldtip) //wahr wenn anderer Tipp

       If(Not($doRefresh)) //gleicher Inhalt

          $doRefresh:=((Abs($x-oldX)>30)|(Abs($y-oldY)>30)) //wahr wenn Cursor bewegt wurde

       End if

 

       If($doRefresh) //anderen Tipp anzeigen

          OBJECT SET HELP TIP(*;"myFlag";$tip)

          oldX:=$x

          oldY:=$y

          oldTip:=$tip

       End if

 

 End case

Beispiel 2

In der Listbox "Commands List" einen Hilfetipp setzen, um die Beschreibung zum Eintrag anzuzeigen. Die Beschreibung liegt in der Tabelle [Documentation].

 C_REAL($mouseX;$mouseY;$mouseZ)

 C_LONGINT($col;$row)

 

 Case of

 

    :(FORM Event=On Mouse Enter)

 

       SET DATABASE PARAMETER(Tips delay;1) // zeigt den Tipp rasch an

 

    :(FORM Event=On Mouse Move)

 

  //#1 : herausfinden, über welche Zeile die Maus zieht

 

       GET MOUSE($mouseX;$mouseY;$mouseZ)

       LISTBOX GET CELL POSITION(*;"Commands List";$mouseX;$mouseY;$col;$row)

 

  //#2 : den passenden Hilfetipp setzen

 

       If($row#0)

          GOTO SELECTED RECORD([Documentation];$row)

          OBJECT SET HELP TIP(*;"Commands List";[Documentation]Description) // Die Beschreibung erscheint im Hilfetipp, wenn die Maus stoppt.

       End if

 

    :(FORM Event=On Mouse Leave)

 

       SET DATABASE PARAMETER(Tips delay;3) // zeigt den Tipp normal an

 

 End case

Das Ergebnis ist...

Siehe auch

OBJECT Get help tip
SET DATABASE PARAMETER