OBJECT SET RGB COLORS

Home

4D v20 R7


OBJECT SET RGB COLORS ( {* ;} Objekt ; Vordergrundfarbe {; Hintergrundfarbe {; altHintergrFarbe}} )

Parameter	Typ	Beschreibung
*	Operator	Mit *: Objekt ist ein Objektname (String), Ohne Stern: Objekt ist Feld oder Variable
Objekt	Formularobjekt	Mit : Objektname, ohne : Feld oder Variable
Vordergrundfarbe	Text, Lange Ganzzahl	RGB Wert für Vordergrundfarbe
Hintergrundfarbe	Text, Lange Ganzzahl	RGB Wert für Hintergrundfarbe
altHintergrFarbe	Text, Lange Ganzzahl	RGB Wert für wechselnde Hintergrundfarbe

Beschreibung

Der Befehl OBJECT SET RGB COLORS ändert die Vordergrund- und Hintergrundfarben der in Objekt angegebenen Objekte. Ist Objekt eine Listbox, können Sie einen weiteren Parameter für wechselnde Vorder- und Hintergrundfarbe für Zeilen mit gerader Nummer verwenden.

Mit dem optionalen Parameter * geben Sie in Objekt einen Objektnamen (String) an. Ohne den optionalen Parameter * geben Sie in Objekt ein Datenfeld oder eine Variable an. In diesem Fall geben Sie anstatt eines Strings eine Referenz auf das Datenfeld oder die Variable an (nur Datenfeld- oder Variablenobjekte). Weitere Informationen dazu finden Sie im Abschnitt Objekteigenschaften.

Der Parameter backgroundColor wird nur bei Objekten berücksichtigt, die das Attribut background color unterstützen.

Mit altHintergrFarbe setzen Sie eine wechselnde Hintergrundfarbe für die Zeilen mit gerader Nummer. Dieser Parameter gilt nur, wenn das angegebene Objekt eine Listbox oder Spalte einer Listbox ist. Dann wird altHintergrFarbe nur für die Hintergrundfarbe der Zeilen mit ungerader Nummer verwendet. Wechselnde Farben machen Arrays leichter lesbar.
Definiert Objekt die Listbox, gilt die wechselnde Farbe für das gesamte Objekt, definiert Objekt eine Spalte, gilt sie nur für die angegebene Spalte.

Farben definieren
In Vordergrundfarbe, Hintergrundfarbe und altHintergrFarbe geben Sie die RGB-Werte an. Folgende Formate werden unterstützt:

Formatname	Typ	Beschreibung	Beispiele
CSS Farbname	Text	Standardmäßiger CSS2 Farbname. Die Liste der verfügbaren Namen finden Sie im Web, z.B. unter htmlcolorcodes.com. Mit "transparent" setzen Sie den Hintergrund auf transparent (nur verwendbar mit den Parametern Hintergrundfarbe und altHintergrFarbe). "" (leerer String) für Vordergrundfarbe bzw. Hintergrundfarbe lässt sie unverändert.	"red", "cyan", "lightblue"
CSS Farbe "#rrggbb" Syntax	Text	Standard CSS2 hex Farbcode: rr = rote Komponente der Farbe gg = grüne Komponente der Farbe bb = blaue Komponente der Farbe	"#ff0000", "#00FFFF", "#ADD8E6"
CSS Farbe"rgb(r,g,b)" Syntax	Text	Standard CSS2 rgb color code: r = rote Komponente der Farbe (0...255) g = grüne Komponente der Farbe (0...255) b = blaue Komponente der Farbe (0...255)	"rgb(255,255,0)", "rgb(255,0,0)"
4-byte RGB Wert	Lange Ganzzahl	4-byte Lange Ganzzahl (format 0x00rrggbb). Hex Werte: rr = rote Komponente der Farbe gg = grüne Komponente der Farbe bb = blaue Komponente der Farbe	0x00000000, 0x00FF7F7F
4D "system" Konstanten für Farben	Lange Ganzzahl	Von 4D verwendete Farben, um Objekte mit automatischen Farben zu setzen. Verfügbare Konstanten unter dem Thema SET RGB COLORS: Background color Background color none (nur mit den Parametern Hintergrundfarbe und altHintergrFarbe verwendbar) Dark shadow color Disable highlight item color Foreground color Highlight menu background color Highlight menu text color Highlight text background color Highlight text color Light shadow color	Hinweis: Die automatischen Farben hängen vom System ab sowie vom Objekttyp, dem sie zugewiesen sind.

Beispiel 1

Dieses Formular enthält zwei nicht eingebbare Variablen vsColorValue und vsColor sowie drei Thermometer: thRed, thGreen und thBlue.

Für diese Objekte gelten folgende Methoden:

  //Objektmethode für nicht-eingebbaren Wert vsColorValue

 Case of

    :(FORM Event=On Load)

       vsColorValue:="0x00000000"

 End case

  // Objektmethode für nicht-eingebbare Variable vsColor

 Case of

    :(FORM Event=On Load)

       vsColor:=""

       OBJECT SET RGB COLORS(vsColor;0x00FFFFFF;0x0000)

 End case

 

  // Objektmethode für Thermomether thRed

 CLICK IN COLOR THERMOMETER

 

  // Objektmethode für Thermometer thGreen

 CLICK IN COLOR THERMOMETER

 

  // Objektmethode für Thermometer thBlue

 CLICK IN COLOR THERMOMETER

Die Thermometer rufen folgende Projektmethode auf:

  // Projektmethode CLICK IN COLOR THERMOMETER

 OBJECT SET RGB COLORS(vsColor;0x00FFFFFF;(thRed<<16)+(thGreen<<8)+thBlue)

 vsColorValue:=String((thRed<<16)+(thGreen<<8)+thBlue;"&x")

 If(thRed=0)

    vsColorValue:=Substring(vsColorValue;1;2)+"0000"+Substring(vsColorValue;3)

 End if

Beachten Sie, dass zum Berechnen der Farbwerte aus dem Thermometer SET AUTOMATIC RELATIONS verwendet werden.

Nach der Ausführung sieht das Formular folgendermaßen aus:

Beispiel 2

In transparenten Hintergrund mit heller Schriftfarbe wechseln:

OBJECT SET RGB COLORS(*;"myVar";Light shadow color;Background color none)

Siehe auch

_o_OBJECT SET COLOR
OBJECT GET RGB COLORS
Select RGB Color