SET WINDOW DOCUMENT ICON

4D v20 R7


SET WINDOW DOCUMENT ICON ( winRef {; imagen}{; archivo} )

Parámetro	Tipo	Descripción
winRef	Entero	Número de referencia de la ventana
imagen	Imagen	Icono personalizado
archivo	Objeto archivo, 4D.Folder	Ruta del archivo o carpeta

Descripción

El comando SET WINDOW DOCUMENT ICON le permite definir un icono para las ventanas en aplicaciones multiventana utilizando una imagen y/o un archivo con la referencia de ventana winRef. El icono será visible dentro de la propia ventana y en la barra de tareas de Windows para ayudar a los usuarios a identificar y navegar por las diferentes ventanas.

Si sólo se pasa archivo, la ventana utiliza el icono correspondiente al tipo de archivo y la ruta del archivo se muestra en el menú de la ventana.
Si sólo se pasa imagen, 4D no muestra la ruta y la imagen pasada se utiliza para el icono de la ventana.
Si se pasan tanto archivo como imagen, la ruta del archivo se muestra en el menú de la ventana y la imagen pasada se utiliza para el icono de la ventana.
Si sólo se pasa winRef o la imagen está vacía, el icono se elimina en macOS y el icono por defecto se muestra en Windows (icono de la aplicación).

Ejemplo

En este ejemplo, queremos crear cuatro ventanas:

Utilizar el icono de la aplicación en Windows y ningún icono en macOS (estado por defecto cuando no se utiliza ninguna imagen o archivo).
Utilizar un icono "usuario"
Asociar un documento a la ventana (para ello se utiliza su icono de tipo de archivo).
Personalizar el icono asociado al documento.

 var $winRef : Integer

 var $userImage : Picture

 var $file : 4D.File

 

  // 1- Abrir el formulario ""Contact"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 SET WINDOW DOCUMENT ICON($winRef)

 DIALOG("Contact";*)

 

  // 2- Abrir el formulario "Contact" con el icono "user"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 SET WINDOW DOCUMENT ICON($winRef;$userImage)

 DIALOG("Contact";*)

 

  // 3- Abrir el formulario "Contact" asociado al documento "user"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$file)

 DIALOG("Contact";*)

 

  // 4- Abrir el fomulario "Contact" asociado al documento "user" con el icono "user"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$userImage;$file)

 DIALOG("Contact";*)

Ver también

Define a different icon for each window (blog post)