SET WINDOW DOCUMENT ICON

4D v20 R7


SET WINDOW DOCUMENT ICON ( winRef {; image}{; file} )

引数	型	説明
winRef	整数	ウィンドウ参照番号
image	ピクチャー	カスタムのアイコン
file	ファイルオブジェクト, 4D.Folder	ファイルパスまたはフォルダパス

説明

SET WINDOW DOCUMENT ICON コマンドを使用するとimage 引数およびfile 引数と、winRef ウィンドウ参照を組み合わせて使用することで、マルチウィンドウアプリケーションにおいてウィンドウ用のアイコンを定義することができます。アイコンはウィンドウ自身にも表示されますし、ウィンドウタスクバーにも表示されるのでユーザーは複数のウィンドウの中でもウィンドウの特定と遷移が容易になります。

file 引数のみが渡された場合、ウィンドウはファイルタイプに対応したアイコンを使用し、ファイルパスがウィンドウのメニュー内に表示されます。
image 引数のみが渡された場合、4D はパスは表示せず、渡された画像がウィンドウアイコンとして使用されます。
file とimage の両方が渡された場合、ファイルのパスがウィンドウのメニューに表示され、渡された画像がウィンドウアイコンとして使用されます。
winRef のみが渡される、またはimage 引数が空の場合、macOS ではアイコンが削除され、Windows ではデフォルトのアイコン(アプリケーションアイコン)が表示されます。

例題

この例題では、以下の4つのウィンドウを作成したい場合を考えます:

Windows ではデフォルトのアプリケーションアイコンを使用し、macOS ではアイコンを使用しない(image もfile も使用しない場合のデフォルトの状態)
"user"アイコンを使用する
ウィンドウにドキュメントを割り当てる(この場合ファイルタイプのアイコンを使用します)。
ドキュメントに割り当てられたアイコンをカスタマイズします。

 var $winRef : Integer

 var $userImage : Picture

 var $file : 4D.File

 

  // 1- "Contact" フォームを開く

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 SET WINDOW DOCUMENT ICON($winRef)

 DIALOG("Contact";*)

 

  // 2- "Contact" フォームを"user" アイコンを割り当てて開く

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 SET WINDOW DOCUMENT ICON($winRef;$userImage)

 DIALOG("Contact";*)

 

  // 3- "Contact" フォームの"user" というドキュメントに割り当てて開く

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$file)

 DIALOG("Contact";*)

 

  // 4- "Contact" フォームに"user" というドキュメントを割り当て、"user" アイコンをに変更して開く

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$userImage;$file)

 DIALOG("Contact";*)

参照

Define a different icon for each window (blog post)