SET WINDOW DOCUMENT ICON

4D v20 R7


SET WINDOW DOCUMENT ICON ( winRef {; image}{; file} )

Paramètre	Type	Description
winRef	Entier	Numéro de référence de la fenêtre
image	Image	Icône personnalisée
file	4D.File, 4D.Folder	Chemin d'accès à un fichier ou à un dossier

Description

La commande SET WINDOW DOCUMENT ICON vous permet de définir une icône pour les fenêtres dans les applications multifenêtres en utilisant une image image et/ou un fichier file avec la référence de fenêtre winRef. L'icône sera visible dans la fenêtre elle-même et dans la barre des tâches pour aider les utilisateurs à identifier les différentes fenêtres et à y naviguer.

Si seul file est transmis, la fenêtre utilise l'icône correspondant au type de fichier et le chemin d'accès au fichier est affiché dans le menu de la fenêtre.
Si seule image est transmise, 4D n'affiche pas le chemin et l'image transmise est utilisée pour l'icône de la fenêtre.
Si file et image sont tous deux transmis, le chemin du fichier est affiché dans le menu de la fenêtre et l'image transmise est utilisée pour l'icône de la fenêtre.
Si seul winRef est transmis ou si image est vide, l'icône est supprimée sous macOS et l'icône par défaut est affichée sous Windows (icône d'application).

Exemple

Dans cet exemple, on souhaite créer quatre fenêtres :

Utiliser l'icône de l'application sous Windows et aucune icône sous macOS (état par défaut lorsqu'aucune image ou file n'est utilisé).
Utiliser une icône “user”.
Associer un document à la fenêtre (cela utilise l'icône du type de fichier).
Personnaliser l'icône associée au document.

 var $winRef : Integer

 var $userImage : Picture

 var $file : 4D.File

 

  // 1- Ouvrez le formulaire "Contact"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 SET WINDOW DOCUMENT ICON($winRef)

 DIALOG("Contact";*)

 

  // 2- Ouvrir le formulaire "Contact" avec l'icône "user".

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 SET WINDOW DOCUMENT ICON($winRef;$userImage)

 DIALOG("Contact";*)

 

  // 3- Ouvrir le formulaire "Contact" associé avec le document "user".

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$file)

 DIALOG("Contact";*)

 

  // 4- Ouvrir le formulaire "Contact" associé avec le document "user" avec l'icône "user".

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$userImage;$file)

 DIALOG("Contact";*)

Voir aussi

Define a different icon for each window (blog post)