SET WINDOW DOCUMENT ICON

Home

4D v20 R7


SET WINDOW DOCUMENT ICON ( winRef {; image}{; file} )

Parameter	Typ	Beschreibung
winRef	Ganzzahl	Window reference number
image	Bild	Custom icon
file	Dateiobjekt, 4D.Folder	File path or folder path

Beschreibung

Mit dem Befehl SET WINDOW DOCUMENT ICON können Sie ein Symbol für Fenster in Anwendungen mit mehreren Fenstern definieren, indem Sie entweder ein image und/oder eine file mit der Fensterreferenz winRef verwenden. Das Symbol wird im Fenster selbst und in der Taskleiste angezeigt, um den Usern die Identifizierung und Navigation in den verschiedenen Fenstern zu erleichtern.

Wenn nur file übergeben wird, verwendet das Fenster das Symbol, das dem Dateityp entspricht, und der Pfad der Datei wird im Menü des Fensters angezeigt.
Wenn nur image übergeben wird, zeigt 4D den Pfad nicht an und das übergebene Bild wird für das Fenstersymbol verwendet.
Wenn sowohl file als auch image übergeben werden, wird der Dateipfad im Menü des Fensters angezeigt und das übergebene Bild wird für das Fenstersymbol verwendet.
Wenn nur winRef übergeben wird oder das image leer ist, wird das Symbol unter macOS entfernt und unter Windows wird das Standardsymbol angezeigt (Applikationssymbol).

Beispiel

In diesem Beispiel möchten wir vier Fenster erstellen:

Verwenden Sie das Symbol der Applikation unter Windows und kein Symbol unter macOS (Standardzustand, wenn kein Bild oder keine Datei verwendet wird).
Verwenden Sie ein „User“-Symbol.
Verknüpfen Sie ein Dokument mit dem Fenster (dazu wird das Symbol des Dateityps verwendet).
Passen Sie das mit dem Dokument verknüpfte Symbol an.

 var $winRef : Integer

 var $userImage : Picture

 var $file : 4D.File

 

  // 1- Öffnen Sie das Formular "Contact"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 SET WINDOW DOCUMENT ICON($winRef)

 DIALOG("Contact";*)

 

  // 2- Öffnen Sie das Formular "Contact" mit dem Symbol "user"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 SET WINDOW DOCUMENT ICON($winRef;$userImage)

 DIALOG("Contact";*)

 

  // 3- Öffnen Sie das Formular "Contact", das mit dem Dokument "user" verbunden ist

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$file)

 DIALOG("Contact";*)

 

  // 4- Öffnen Sie das Formular "Contact" für das Dokument "user" mit dem Symbol "user"

 $winRef:=Open form window("Contact";Plain form window+Form has no menu bar)

 BLOB TO PICTURE(File("/RESOURCES/icon/user.png").getContent();$userImage)

 $file:=File("/RESOURCES/files/user.txt")

 SET WINDOW DOCUMENT ICON($winRef;$userImage;$file)

 DIALOG("Contact";*)

Siehe auch

Define a different icon for each window (blog post)