Open window

Home

4D v20 R7

Open window


Open window ( Links ; Oben ; Rechts ; Unten {; Typ {; Titel {; Schließen}}} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
Links	Lange Ganzzahl	Linke Position des Fensters
Oben	Lange Ganzzahl	Obere Position des Fensters
Rechts	Lange Ganzzahl	Rechte Position des Fensters oder -1 für Standardgröße des Formulars
Unten	Lange Ganzzahl	Untere Position des Fensters oder -1 für Standardgröße des Formulars
Typ	Lange Ganzzahl	Typ des Fensters
Titel	String	Titel des Fensters oder "" für Standardtitel des Formulars
Schließen	String	Aufzurufende Methode bei Doppelklick auf die Kontrollmenü-Box oder Klick auf Schließbox
Funktionsergebnis	WinRef	Referenznummer des Fensters

Beschreibung

Die Funktion Open window öffnet ein neues Fenster mit den in den ersten vier Parametern angegebenen Werten.

Links ist der Abstand in Pixel vom linken Rand des Anwendungsfensters zum linken inneren Rand des Fensters.
Oben ist der Abstand in Pixel vom oberen Rand des Anwendungsfensters zum oberen inneren Rand des Fensters.
Rechts ist der Abstand in Pixel vom linken Rand des Anwendungsfensters zum rechten inneren Rand des Fensters.
Unten ist der Abstand in Pixel vom oberen Rand des Anwendungsfensters zum unteren inneren Rand des Fensters.

Hinweis zur Kompatibilität: Open window bietet eine Reihe von Optionen, die über die Jahre weiterentwickelt wurden und nur zur Wahrung der Kompatibiltät beibehalten werden. Schreiben Sie neuen Code zum Verwalten von Fenstern, empfehlen wir, die Funktion Open form window zu verwenden, da sie sich für die aktuellen Oberflächen besser eignet.

Übergeben Sie für Rechts und Unten den Wert -1, legt 4D unter folgenden Bedingungen automatisch die Größe des Fensters fest:

Sie haben im Designmodus ein Formular erstellt und seine Ausmaße im Fenster Formulareigenschaften festgelegt.
Sie haben vor dem Aufruf von Open window das Formular mit dem Befehl FORM SET INPUT ausgewählt und den optionalen Parameter * übergeben.

Wichtig: Das Fenster wird nur automatisch angepasst, wenn Sie zuvor für das anzuzeigende Formular den Befehl FORM SET INPUT aufgerufen und den optionalen Parameter * übergeben haben.

Der Parameter Typ ist optional. Damit bestimmen Sie den Fenstertyp. Die verschiedenen Typen werden im Abschnitt Fenstertypen (Kompatibilität) beschrieben. Geben Sie diesen Wert nicht an, wird standardmäßig der Typ 1 verwendet. Übergeben Sie einen negativen Wert, verhält sich das Fenster wie ein Palettenfenster. Es liegt immer auf dem Bildschirm ganz vorne, außer es erscheint ein Dialogfenster.
Der Parameter Titel ist der optionale Titel für das Fenster. Bei Fenstertypen ohne Titelleiste hat er keine Wirkung.

Übergeben Sie in Titel einen leeren String (""),verwendet 4D für das anzuzeigende Formular den Fenstertitel, der im Designmodus im Fenster Formulareigenschaften festgelegt wurde.

Wichtig: Der Standardtitel des Formulars wird nur eingesetzt, wenn Sie zuvor für das anzuzeigende Formular den Befehl FORM SET INPUT aufgerufen und den optionalen Parameter * übergeben haben.

Der Parameter Schließen ist ebenfalls optional. Er erwartet einen Methodennamen. Wird der Parameter angegeben, erscheint unter Windows eine Kontrollmenü-Box, auf Macintosh eine Schließbox. Mit einem Doppelklick auf die Kontrollmenübox bzw. einem Klick auf die Schließbox ruft der Anwender die in Schließen angegebene Methode auf. Sie muss eine Bestätigen- oder Abbrechen-Anweisung enthalten.

Hinweis: Sie können auch das Schließen des Fensters über eine Formularmethode des im Fenster angezeigten Formulars verwalten, wenn ein Ereignis On Close Box eintritt. Weitere Informationen dazu finden Sie unter der Funktion Form event code.

Öffnen Sie während eines Prozesses mehrere Fenster, ist das zuletzt geöffnete das aktive Fenster. Sie können nur die Informationen in diesem Fenster verändern. Die Daten in den anderen Fenstern werden jedoch weiterhin angezeigt. Gibt der Anwender Daten ein, kommt das für diesen Prozess aktive Fenster ganz nach vorne.

Formulare werden innerhalb eines offenen Fensters angezeigt. Text vom Befehl MESSAGE erscheint ebenso im Fenster.

Open window gibt eine Referenz vom Typ WinRef zurück, welche die Befehle zur Fensterverwaltung nutzen können. Weitere Informationen dazu finden Sie im Abschnitt WinRef.

Beispiel 1

Folgende Projektmethode öffnet unter Windows innerhalb des Hauptfensters, auf Macintosh im Hauptbildschirm ein zentriertes Fenster. Beachten Sie, dass es zwei, drei oder vier Parameter haben kann:

  ` Projektmethode OPEN CENTERED WINDOW

  ` $1 – Fensterbreite

  ` $2 – Fensterhöhe

  ` $3 – Fenstertyp (optional)

  ` $4 – Fenstertitel (optional)

 $SW:=Screen width\2

 $SH:=(Screen height\2)

 $WW:=$1\2

 $WH:=$2\2

 Case of

    :(Count parameters=2)

       Open window($SW-$WW;$SH-$WH;$SW+$WW;$SH+$WH)

    :(Count parameters=3)

       Open window($SW-$WW;$SH-$WH;$SW+$WW;$SH+$WH;$3)

    :(Count parameters=4)

       Open window($SW-$WW;$SH-$WH;$SW+$WW;$SH+$WH;$3;$4)

 End case

Diese Projektmethode können Sie beispielsweise so einsetzen:

 OPEN CENTERED WINDOW(400;250;Movable dialog box;"Update Archives")

 DIALOG([Utility Table];"UPDATE OPTIONS")

 CLOSE WINDOW

 If(OK=1)

  ` ...

 End if

Beispiel 2

Folgendes Beispiel öffnet ein Palettenfenster, das eine Methode für die Kontrollmenü-Box (Windows) bzw. Schließbox (Macintosh) enthält. Dieses Fenster öffnet sich in der oberen rechten Ecke des Anwendungsfensters.

 $myWindow=Open window(Screen width-149;33;Screen width-4;178;-Palette window;"";"Schließe Farbpalette")

 DIALOG([Dialogs];"Farbpalette")

Die Methode CloseColorPalette ruft den Befehl CANCEL auf:

CANCEL

Beispiel 3

Folgendes Beispiel öffnet ein Fenster, das die Größe und Titel über die Eigenschaften des im Fenster angezeigten Formulars erhält:

 FORM SET INPUT([Customers];"Füge Datensätze hinzu";*)

 $myWindow=Open window(10;80;-1;-1;Plain window;"")

 Repeat

    ADD RECORD([Customers])

 Until(OK=0)

Bitte beachten: Open window verwendet nur dann automatisch die Einstellungen des Formulars, wenn Sie zuvor den Befehl FORM SET INPUT mit dem optionalen Parameter * aufgerufen haben und in der Designumgebung entsprechende Formulareigenschaften festgelegt haben.

Beispiel 4

Folgendes Beispiel zeigt unter Mac OS X, wie sich die Anzeige eines Sheet Fensters verzögern lässt:

 $myWindow:=Open window(10;10;400;400;Sheet window)

  `Das Fenster wird erstellt, bleibt jedoch ausgeblendet.

 DIALOG([Table];"dialForm")

  `Das Ereignis On Load wird erstellt, dann rollt das Sheet Fenster von der Titelleiste her auf.

Siehe auch

CLOSE WINDOW
Open form window
Open Window