WA SET URL FILTERS

Home

4D v20 R7

WA SET URL FILTERS


WA SET URL FILTERS ( {* ;} Objekt ; FilterArr ; ErlaubenVerweigernArr )

Parameter	Typ	Beschreibung
*	Operator	Mit * ist Objekt ein Objektname (String), ohne * ist Objekt eine Variable
Objekt	Formularobjekt	Objektname (mit ) oder Variable (ohne )
FilterArr	Array String	Filter Array
ErlaubenVerweigernArr	Array Boolean	Erlauben-Verweigern Array

Beschreibung

Der Befehl WA SET URL FILTERS richtet einen oder mehrere Filter für den Web Bereich ein, definiert durch die Parameter * und Objekt.

Vor dem Laden einer angefragten Seite konsultiert 4D die Filterliste, ob die Ziel-URL erlaubt ist oder nicht. Die Bewertung richtet sich nach dem Inhalt der Arrays FilterArr und ErlaubenVerweigernArr.

Nicht-erlaubte URLs werden nicht geladen und das Formularereignis On URL Filtering wird erzeugt.

Die Arrays FilterArr und ErlaubenVerweigernArr müssen aufeinander abgestimmt sein.

Jedes Element von FilterArr muss eine URL zum Filtern enthalten. Sie können den * als Joker einsetzen, um ein oder mehrere Zeichen zu ersetzen.
Jedes entsprechende Element im Array ErlaubenVerweigernArr muss einen Boolean Wert haben, d.h. Wahr für erlaubt, Falsch für verweigert.

Bei einem Widerspruch auf der Konfigurationsebene (dieselbe URL ist erlaubt und verweigert), wird die letzte Einstellung berücksichtigt.

Um das Filtern der URL zu deaktivieren, rufen Sie den Befehl auf und übergeben leere Arrays oder in den letzten Elementen der beiden Arrays FilterArr und ErlaubenVerweigernArr jeweils die Werte "*" und Wahr.

Nach Ausführen des Befehls werden die Filter dem Web Bereich als Eigenschaft zugeordnet. Werden die Arrays FilterArr und ErlaubenVerweigernArr gelöscht oder neu initialisiert, bleiben die Filter aktiv, solange der Befehl nicht erneut ausgeführt wird. Über den Befehl WA GET URL FILTERS können Sie den aktiven Filter für einen Bereich herausfinden.

Wichtig: Das Filtern der URLs durch diesen Befehl gilt für jede Anfrage zum Ändern der primären "URL" der Seite, sei es über den Benutzer, Javascript Code oder 4D Code, mit Ausnahme von WA OPEN URL und URLs, die mit "javascript:" beginnen.

Beispiel 1

Sie wollen den Zugriff auf alle Web Sites mit dem Kürzel .org, .net und .fr verweigern:

 ARRAY TEXT($filters;0)

 ARRAY BOOLEAN($AllowDeny;0)

 

 APPEND TO ARRAY($filters;"*.org")

 APPEND TO ARRAY($AllowDeny;False)

 APPEND TO ARRAY($filters;"*.net")

 APPEND TO ARRAY($AllowDeny;False)

 APPEND TO ARRAY($filters;"*.fr")

 APPEND TO ARRAY($AllowDeny;False)

 WA SET URL FILTERS(MyWArea;$filters;$AllowDeny)

Beispiel 2

Sie wollen den Zugriff auf alle Web Sites mit Ausnahme der russischen (.ru) verweigern:

 ARRAY TEXT($filters;0)

 ARRAY BOOLEAN($AllowDeny;0)

 

 APPEND TO ARRAY($filters;"*") `Alle auswählen

 APPEND TO ARRAY($AllowDeny;False) `Alle verweigern

 APPEND TO ARRAY($filters;"www.*.ru") ` *.ru auswählen

 APPEND TO ARRAY($AllowDeny;True) `Erlauben

 WA SET URL FILTERS(MyWArea;$filters;$AllowDeny)

Beispiel 3

Sie wollen nur den Zugriff auf die Web Sites von 4D erlauben (.com, .fr, .es, etc.):

 ARRAY TEXT($filters;0)

 ARRAY BOOLEAN($AllowDeny;0)

 

 APPEND TO ARRAY($filters;"*") `Alle auswählen

 APPEND TO ARRAY($AllowDeny;False) `Alle verweigern

 APPEND TO ARRAY($filters;"www.4D.*") `4d.fr, 4d.com... auswählen

 APPEND TO ARRAY($AllowDeny;True) `Erlauben

 WA SET URL FILTERS(MyWArea;$filters;$AllowDeny)

Beispiel 4

Sie wollen nur lokalen Zugriff auf die Dokumentation erlauben (im Ordner C://doc):

 ARRAY TEXT($filters;0)

 ARRAY BOOLEAN($AllowDeny;0)

 

 APPEND TO ARRAY($filters;"*") `Alle auswählen

 APPEND TO ARRAY($AllowDeny;False) `Alle verweigern

 APPEND TO ARRAY($filters;"file://C:/doc/*")

  `Pfad Datei:// erlaubt auswählen

 APPEND TO ARRAY($AllowDeny;True) `Erlauben

 WA SET URL FILTERS(MyWArea;$filters;$AllowDeny)

Beispiel 5

Sie wollen den Zugriff auf alle Web Sites erlauben, mit einer Ausnahme, zum Beispiel die Site Elcaro:

 ARRAY TEXT($filters;0)

 ARRAY BOOLEAN($AllowDeny;0)

 

 APPEND TO ARRAY($filters;"*")

 APPEND TO ARRAY($AllowDeny;True) `Alle erlauben

 APPEND TO ARRAY($filters;"*elcaro*") `Alle verweigern, die el caro enthalten

 APPEND TO ARRAY($AllowDeny;False)

 WA SET URL FILTERS(MyWArea;$filters;$AllowDeny)

Beispiel 6

Sie wollen den Zugriff auf bestimmte IP Adressen verweigern:

 ARRAY TEXT($filters;0)

 ARRAY BOOLEAN($AllowDeny;0)

 

 APPEND TO ARRAY($filters;"*") `Alle auswählen

 APPEND TO ARRAY($AllowDeny;True) `Alle erlauben

 APPEND TO ARRAY($filters;"86.83.*") `IP Adressen wählen, die mit 86.93 beginnen.

 APPEND TO ARRAY($AllowDeny;False) `Verweigern

 APPEND TO ARRAY($filters;"86.1*")

  `IP Adressen wählen, die mit 86.1 beginnen (86.10, 86.135 etc)

 APPEND TO ARRAY($AllowDeny;False) `Verweigern

 WA SET URL FILTERS(MyWArea;$filters;$AllowDeny)

  `Beachten Sie, dass die IP Adresse eines Domain variieren kann.

Siehe auch

WA GET URL FILTERS
WA SET EXTERNAL LINKS FILTERS