Null

Home

4D v20 R7

Null


Null -> Funktionsergebnis

Parameter	Typ	Beschreibung
Funktionsergebnis	Null	Nullwert

Beschreibung

Die Funktion Null gibt den Wert Null vom Typ null zurück.

Mit dieser Funktion können Sie den Wert Null zuweisen oder mit folgenden Elementen der Programmiersprache vergleichen:

Elemente der Programmiersprache	Befehle
Werte der Objekteigenschaft	Vergleich von Null mit einer Objekteigenschaft gibt wahr zurück, wenn der Wert der Eigenschaft Null ist; sonst falsch. Zur Vereinfachung des Code gibt Null auch wahr zurück, wenn die Eigenschaft im Objekt nicht existiert (ist z.B. Undefined ), siehe Beispiel 5.
Collection Elemente	Wird eine Collection mit nicht-zusammenhängenden Elementen erweitert, erhalten alle dazwischenliegenden Elemente automatisch den Wert Null.
Objekt Variablen (_O_C_OBJECT)	Wird der Wert Null diesem Variablentyp zugewiesen, wird sein Inhalt gelöscht. In diesem Fall hat die Funktion denselben Effekt wie Aufrufen von CLEAR VARIABLE.
Collection Variablen (_O_C_COLLECTION)	Wird der Wert Null diesem Variablentyp zugewiesen, wird sein Inhalt gelöscht. In diesem Fall hat die Funktion denselben Effekt wie Aufrufen von CLEAR VARIABLE.
Zeiger Variablen (_O_C_POINTER)	Wird der Wert Null diesem Variablentyp zugewiesen, wird sein Inhalt gelöscht. In diesem Fall hat die Funktion denselben Effekt wie Aufrufen von CLEAR VARIABLE.
Bild Variablen (_O_C_PICTURE)	() Wird der Wert Null* diesem Variablentyp zugewiesen, wird sein Inhalt gelöscht. In diesem Fall hat die Funktion denselben Effekt wie Aufrufen von CLEAR VARIABLE.
Variant Variablen (_O_C_VARIANT)

Hinweis: Diese Funktion lässt sich nicht mit skalaren Feldern der Datenbank verwenden. Nullwerte in Feldern der Datenbank werden von der SQL Engine verwaltet und über die Befehle Is field value Null und SET FIELD VALUE NULL verwaltet.

Beispiel 1

Den Wert Null für eine Objekteigenschaft zuweisen und testen:

 C_OBJECT(vEmp)

 vEmp:=New object

 vEmp.name:="Smith"

 vEmp.children:=Null

 

 If(vEmp.children=Null) //wahr

 End if

 If(vEmp.name=Null) //falsch

 End if

 If(vEmp.parent=Null) //wahr

 End if

Hinweis: Für dieses Beispiel muss die Objekt Notation in den Struktureinstellungen aktiviert sein.

Beispiel 2

Den Wert Null einem Collection Element zuweisen und vergleichen:

 C_COLLECTION(myCol)

 myCol:=New collection(10;20;Null)

 ...

 If(myCol[2]=Null)

  // wenn das 3. Element null ist

    ...

 End if

Beispiel 3

Diese Beispiele zeigen verschiedene Wege, um Variablen den Wert Null zuzuweisen oder zu vergleichen:

  //Objektvariable

 C_OBJECT($o)

 $o:=New object

 $o:=Null //entspricht CLEAR VARIABLE($o)

 If($o#Null) //entspricht If (OB Is defined($o))

 End if

  //Collection-Variable

 C_COLLECTION($c)

 $c:=New collection

 $c:=Null //entspricht CLEAR VARIABLE($c)

 If($c#Null)

 End if

  //Zeigervariable

 C_POINTER($p)

 $p:=->$v

 $p:=Null //entspricht CLEAR VARIABLE($p)

 If($p=Null) //entspricht If (Is Nil pointer($p))

 End if

  //Bildvariable

 C_PICTURE($i)

 $i:=$vpicture

 $i:=Null //entspricht CLEAR VARIABLE($i)

 If($i#Null) //entspricht If (Picture size($i)#0)

 End if

Beispiel 4

Hier sehen Sie je nach Kontext unterschiedliche Ergebnisse der Funktionen Undefined und Null mit Objekteigenschaften:

 C_OBJECT(vEmp)

 vEmp:=New object

 vEmp.name:="Smith"

 vEmp.children:=Null

 

 $undefined:=Undefined(vEmp.name) // Falsch

 $null:=(vEmp.name=Null) //Falsch

 

 $undefined:=Undefined(vEmp.children) // Falsch

 $null:=(vEmp.children=Null) //Wahr

 

 $undefined:=Undefined(vEmp.parent) // Wahr

 $null:=(vEmp.parent=Null) //True

Siehe auch

Is field value Null
OB SET NULL
SET FIELD VALUE NULL