entitySelection.drop( )

Home

4D v19.8


entitySelection.drop ( {mode} ) -> Result

Parameter	Type	Description
mode	Longint	dk stop dropping on first error: stops method execution on first non-droppable entity
Result	EntitySelection	Empty entity selection if successful, else entity selection containing non-droppable entity(ies)

Description

The entitySelection.drop( ) method removes the entities belonging to the entity selection from the table related to its dataclass within the datastore. The entity selection remains in memory.

Note: Removing entities is permanent and cannot be undone. It is recommended to call this action in a transaction in order to have a rollback option.

If a locked entity is encountered during the execution of entitySelection.drop( ), it is not removed. By default, the method processes all entities of the entity selection and returns non-droppable entities in the entity selection. If you want the method to stop execution at the first encountered non-droppable entity, pass the dk stop dropping on first error constant in the mode parameter.

Example

Example without the dk stop dropping on first error option:

 C_OBJECT($employees;$notDropped)

 $employees:=ds.Employee.query("firstName=:1";"S@")

 $notDropped:=$employees.drop() // $notDropped is an entity selection containing all the not dropped entities

 If($notDropped.length=0) //The delete action is successful, all the entities have been deleted

    ALERT("You have dropped "+String($employees.length)+" employees") //The dropped entity selection remains in memory

 Else

    ALERT("Problem during drop, try later")

 End if

Example with the dk stop dropping on first error option:

 C_OBJECT($employees;$notDropped)

 $employees:=ds.Employee.query("firstName=:1";"S@")

 $notDropped:=$employees.drop(dk stop dropping on first error) //$notDropped is an entity selection containing the first not dropped entity

 If($notDropped.length=0) //The delete action is successful, all the entities have been deleted

    ALERT("You have dropped "+String($employees.length)+" employees") //The dropped entity selection remains in memory

 Else

    ALERT("Problem during drop, try later")

 End if