entitySelection.refresh( )

Home

4D v19.8


	entitySelection.refresh ()

	Does not require any parameters

Description

Note: This method only works with a remote datastore (client / server or Open datastore connection).

The entitySelection.refresh( ) method immediately "invalidates" the entity selection data in the local ORDA cache so that the next time 4D requires the entity selection, it will be reloaded from the database.

By default, the local ORDA cache is invalidated after 30 seconds. In the context of client / server applications using both ORDA and the classic language, this method allows you to make sure a remote application will always work with the latest data.

Example 1

In this example, classic and ORDA code modify the same data simultaneously:

  //On a 4D remote

 

 C_OBJECT($selection;$student)

 

 $selection:=ds.Students.query("lastname=:1";"Collins")

  //The first entity is loaded in the ORDA cache

 $student:=$selection.first()

 

  //Update with classic 4D, ORDA cache is not aware of if

 QUERY([Students];[Students]lastname="Collins")

 [Students]lastname:="Colin"

 SAVE RECORD([Students])

 

  //to get the latest version, the ORDA cache must be invalidated

 $selection.refresh()

  // Even if cache is not expired, the first entity is reloaded from disk

 $student:=$selection.first()

 

  //$student.lastname contains "Colin"

Example 2

A list box displays the Form.students entity selection and several clients work on it.

  // Form method:

 Case of

    :(Form event code=On Load)

       Form.students:=ds.Students.all()

 End case

  //

  //

  // On client #1, the user loads, updates, and saves the first entity

  // On client #2, the user loads, updates, and saves the same entity

  //

  //

  // On client #1:

 Form.students.refresh() // Invalidates the ORDA cache for the Form.students entity selection

  // The list box content is refreshed from the database with update made by client #2