Application version

Home

4D v20 R7

Application version


Application version {( ErstellungsNr {; *} )} -> Funktionsergebnis

Parameter	Typ	Beschreibung
ErstellungsNr	Lange Ganzzahl	Nummer der Erstellung
*	Operator	Mit : Lange Versionsnummer Ohne : Kurze Versionsnummer
Funktionsergebnis	String	Zeichenkette mit codierter Versionsnummer

Beschreibung

Die Funktion Application version gibt einen codierten String Wert zurück, der die Versionsnummer der eingesetzten 4D Umgebung anzeigt.

Übergeben Sie keinen optionalen * Parameter, wird eine vierstellige Zeichenkette mit folgender Formatierung zurückgegeben:

Zeichen Beschreibung
1-2 Versionsnummer
3 "R" Nummer
4 Revision Nummer

Übergeben Sie einen optionalen * Parameter, wird eine achtstellige Zeichenkette mit folgender Formatierung zurückgegeben:

Zeichen	Beschreibung
1	"F" kennzeichnet eine Final Version
	"B" kennzeichnet eine Beta Version
	Andere Zeichen kennzeichnen eine 4D-interne Version
2-3-4	Interne 4D Kompilierungsnummer
5-6	Versionsnummer
7	"R" Nummer
8	Revision Nummer

Hinweis zur Kompatibilität (4D v14)

Die Nummerierung der Version hat sich mit 4D Version 14 geändert:

Die "R" Nummer ist die Nummer der "R" Version von 4D (enthält 0 für eine Bugfix Version),
Die Revision Nummer ist die Nummer der Bugfix Version von 4D (enthält 0 für eine "R" Version).

In bisherigen Versionen von 4D war die Nummer der "R" Version die Update Nummer; sie bezeichnete die Revision und die Revision Nummer selbst war immer 0.

Beispiele für kurze Versionsnummer:

Version	zurückgegebener Wert
4D v13.1	"1310"	Bisheriges Nummerierungssystem
4D v14 R2	"1420"	4D v14 Release R2
4D v14 R3	"1430"	4D v14 Release R3
4D v14.1	"1401"	Erste Bugfix Revision von 4D v14
4D v14.2	"1402"	Zweite Bugfix Revision von 4D v14

Beispiele für lange Versionsnummer:

Version	zurückgegebener Wert
4D v12.5 beta	"B0011250"
4D v14 beta R2	"B0011420"
4D v14 final R3	"F0011430"
4D v14.1 beta	"B0011401"

Die Funktion Application version kann über den optionalen Parameter ErstellungsNr zusätzliche Information zurückgeben: Die Erstellungsnummer (Build number) der aktuellen Version der 4D Anwendung. Dies ist eine interne Kompilierungsnummer, die zur Festlegung der Version oder über die Abteilung 4D Technical Services vergeben werden kann.

Hinweis: Bei Anwendungen mit einkompilierter 4D Volume License ist die zurückgegebene Erstellungsnummer nicht signifikant. In diesem Kontext verwaltet der Entwickler die Informationen zur Version.

Beispiel 1

Dieses Beispiel zeigt die Versionsnummer der 4D Umgebung:

 $vs4Dversion:=Application version

 ALERT("Sie verwenden die Version "+String(Num(Substring($vs4Dversion;1;2)))

 +"."+$vs4Dversion[[3]]+"."+$vs4Dversion[[4]])

Beispiel 2

Dieses Beispiel überprüft, ob Sie die Final Version verwenden:

 If(Substring(Application version(*);1;1)#"F")

    ALERT("Stelle sicher, dass mit dieser Datenbank die Final Version von 4D verwendet wird!")

    QUIT 4D

 End if

Beispiel 3

Folgender Code erstellt die Versionsnummer der Anwendung und ermöglicht die Unterscheidung zwischen "R" Releases und "Bug fix" Revisions:

 C_LONGINT($Lon_build)

 C_TEXT($Txt_info;$Txt_major;$Txt_minor;$Txt_release;$Txt_version)

 

 $Txt_version:=Application version($Lon_build)

 

 $Txt_major:=$Txt_version[[1]]+$Txt_version[[2]] //Versionsnummer, z.B. 14

 $Txt_release:=$Txt_version[[3]] //Rx

 $Txt_minor:=$Txt_version[[4]] //.x

 

 $Txt_info:="4D v"+$Txt_major

 If($Txt_release="0") //4D v14.x

    $Txt_info:=$Txt_info+Choose($Txt_minor#"0";"."+$Txt_minor;"")

 

 Else //4D v14 Rx

    $Txt_info:=$Txt_info+" R"+$Txt_release

 End if

Siehe auch

Application type
Version type