WP Table get cells

4D v19

WP Table get cells


WP Table get cells ( targetObj ) \| ( tableRef ; startCol ; startRow {; numCols{; numRows}} ) -> 戻り値

引数	型	説明
targetObj	オブジェクト	レンジまたは要素または4D Write Pro ドキュメント
tableRef	オブジェクト	テーブル参照オブジェクト
startCol	倍長整数	先頭セルの位置 (カラム)
startRow	倍長整数	先頭セルの位置 (行)
numCols	倍長整数	取得するカラムの数
numRows	倍長整数	取得する行の数
戻り値	オブジェクト	指定セルを含む新規レンジ

説明

WP Table get cells コマンドは、 targetObj または(startCol、startRow、numCols、および numRows 引数で定義された)tableRef で指定した表から、セルのセレクションを格納した新しいレンジオブジェクトを返します。

以下のいづれかを渡します:

targetObj 引数の場合、渡せるもの:
- レンジ
- 要素(行/段落/本文/ヘッダー/フッター/インラインピクチャー/セクション/サブセクション)
- 4D Write Pro ドキュメント

targetObj 引数が、表、またはセルのセレクションを取得可能なテキストレンジと交差しない場合、コマンドはNull を返します。

または

startCol および startRow 引数 - 取得したい最初のセル範囲の左上端の座標を定義します。
(オプション) numCols および numRows 引数 - それぞれセルレンジとして取得したいカラムと行の数を指定します。

numRows 引数が省略された場合、単一の行が返されます。numCols および numRows 引数の両方が省略された場合、返されたレンジには単一のセルのみが格納されます。

startCol と numCols を足した数、もしくはstartRow と numRows を足した数がtableRef 引数で指定した表のカラム数/行数より多い場合、またはstartCol or startRow 引数そのものがtableRef 引数で指定した表のカラム数/行数より多い場合、返されるレンジには取得可能なカラム/行が全て格納されます。

例題 1

特定のセル範囲の属性を変更します:

 C_OBJECT($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$cells)

 $wpRange:=WP Create range(WParea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Table append row($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Table append row($wpTable;"Henry";"Cartier";42)

 

 $cells:=WP Table get cells($wpTable;2;2;2;2)

 WP SET ATTRIBUTES($cells;wk background color;0x00E0E0E0)

 WP SET ATTRIBUTES($cells;wk text color;"blue")

 WP SET ATTRIBUTES($cells;wk border color;0x00E000E0)

 WP SET ATTRIBUTES($cells;wk text align;wk center)

結果:

例題 2

"5x7"のセルから行の最後までのセルのレンジを取得する場合を考えます:

$cellRange:=WP Table get cells(tableRef;5;7;MAXLONG;1)

"5x7"のセルからカラムの最後までのセルのレンジを取得する場合を考えます:

$cellRange:=WP Table get cells(tableRef;5;7;1;MAXLONG)

"5x7"のセルからテーブルの最後までのセルのレンジを取得する場合を考えます:

$cellRange:=WP Table get cells(tableRef;5;7;MAXLONG;MAXLONG)

例題 3

ユーザーが選択したセルを取得したい場合を考えます:

 C_OBJECT($userSelection;$cells)

 

 $userSelection:=WP Selection range(myWPArea)

 

 $cells:=WP Table get cells($userSelection)

参照

WP Table get columns
WP Table get rows