WP EXPORT DOCUMENT

Home

4D v20 R7

WP EXPORT DOCUMENT


WP EXPORT DOCUMENT ( wpDoc ; DateiPfad {; Format {; Option}} )

Parameter	Typ	Beschreibung
wpDoc	Objekt	Objekt 4D Write Pro
DateiPfad	String	Pfad der exportierten Datei
Format	Lange Ganzzahl	Ausgabeformat des Dokuments
Option	Objekt, Lange Ganzzahl	Exportoptionen

Beschreibung

Der Befehl WP EXPORT DOCUMENT exportiert das Objekt 4D Write Pro wpDoc mit dem Parameter DateiPfad sowie optionalen Parametern in ein Dokument auf der Festplatte.

In wpDoc übergeben Sie das Objekt 4D Write Pro zum Exportieren.

In DateiPfad übergeben Sie den Zielpfad und den Namen des zu exportierenden Dokuments. Übergeben Sie nur den Dokumentnamen, wird es auf derselben Ebene wie die 4D Strukturdatei gesichert. Standardmäßig, d.h. ohne den Parameter Format, wählt der Befehl das Dateiformat anhand der Endung des Dokuments aus.

Sie können den Parameter format weglassen. In diesem Fall müssen Sie die Erweiterung in filePath angeben. Sie können auch eine Konstante aus dem 4D Write Pro Konstanten Thema im Parameter format übergeben. In diesem Fall fügt 4D bei Bedarf die entsprechende Erweiterung zum Dateinamen hinzu. Die folgenden Formate werden unterstützt:

Konstante	Wert	Kommentar
wk 4wp	4	Das 4D Write Pro Dokument wird in einem nativen Archivformat gesichert (gezipptes HTML und Bilder in einem eigenen Ordner abgelegt). 4D spezifische Tags sind enthalten, 4D Ausdrücke werden nicht berechnet. Dieses Format ist besonders geeignet, um 4D Write Pro Dokumente ohne Verluste auf der Festplatte zu sichern und archivieren.
wk docx	7	Endung .docx. 4D Write Pro Dokument wird im Microsoft Word Format gesichert. Zertifizierte Unterstützung für Microsoft Word 2016 und neuer, jedoch kompatibel mit jeder Version, die das Format .docx unterstützt (z.B. Microsoft Word 2013). Die exportierten Dokumentteile sind: Hauptteil / Kopfteil / Fußteil / Abschnitte Seite / Druckeinstellungen (Abstände, Hintergrundfarbe / -bild, Rahmen, Einrückung, Papiergröße / Ausrichtung) Bilder - im Text eingebunden, verankert und Muster für Hintergrundbild (definiert mit wk background image) Kompatible Variablen und Ausdrücke (Seitenzahl, Anzahl Seiten, Datum, Zeit, Metadaten). Nicht-kompatible Variablen und Ausdrücke werden vor dem Export bewertet und eingefroren. Lesezeichen Beachten Sie, dass einige Einstellungen von 4D Write Pro in Microsoft Word u.U. nicht verfügbar sind oder sich anders verhalten können.
wk mime html	1	Das 4D Write Pro Dokument wird als standard MIME HTML mit html Dokumenten und Bildern, eingebunden als MIME Teile (codiert in base64), gesichert. Ausdrücke werden berechnet und 4D spezifische Tags werden entfernt. Dieses Format eignet sich besonders, um E-Mails in HTML mit dem Befehl zu senden.
wk pdf	5	.pdf Endung. 4D Write Pro Dokument wird im PDF Format gesichert, basierend auf die Modus Seitenansicht. Folgende Metadaten werden in ein PDF Dokument exportiert: title author subject Content creator Hinweise: Ausdrücke werden beim Exportieren des Dokuments automatisch eingefroren Links zu Methoden werden NICHT exportiert
wk svg	8	Die 4D Write Pro Dokumentseite wird im SVG-Format gespeichert, basierend auf dem Seitenansichtsmodus. Hinweis: Beim Export in das SVG-Format können Sie immer nur eine Seite exportieren. Verwenden Sie das wk page index, um die zu exportierende Seite anzugeben.
wk web page complete	2	Endung .htm oder .html. Das Dokument wird als Standard HTML gesichert, seine Ressourcen werden getrennt gesichert. 4D Tags werden entfernt und Ausdrücke berechnet. Dieses Format ist besonders geeignet, um ein 4D Write Pro Dokument in einem Web Browser anzuzeigen.

Hinweise:

"4D spezifische tags" bedeutet 4D XHTML mit einem 4D Namensbereich und 4D CSS Stilarten
Weitere Informationen zum 4D Write Pro Format finden Sie im Abschnitt Dokumentformat .4wp
Weitere Informationen zum Format .docx, insbesondere die Liste der bekannten Unterschiede oder nicht kompatiblen Features, finden Sie unter Import und Export im Format .docx
Weitere Informationen zum Export in das SVG-Format finden Sie unter Exporting to SVG format.

Parameter Option

Im Parameter Option übergeben Sie ein Objekt mit den Werten zum Definieren der Eigenschaften des exportierten Dokuments. Es gibt folgende Konstanten:

Konstante	Wert	Kommentar
wk CID host domain name	cidHostDomain	Name des CID Host Domain: Host Domain, das zu generierten CID URLs hinzugefügt wird, mit einem '@' als Trenner. Nur verfügbar, wenn das Format wk mime html verwendet wird.
wk embedded pictures	embeddedPictures	Nur für SVG-Export. Legt fest, ob Bilder in die exportierte .svg-Datei eingebettet werden, wenn Sie WP EXPORT DOCUMENT aufrufen. Verfügbare Werte: true (Standard): Bilder werden in die exportierte .svg-Datei eingebettet falsch: Die Bilder werden in einen Ordner namens "filename_images" auf der Ebene der exportierten .svg-Datei exportiert, wobei "filename" der Name ist, der dem Befehl für die Datei übergeben wurde, ohne die Erweiterung. Die Bilder werden nicht eingebettet, sondern in der .svg-Datei referenziert. Beachten Sie das: Wenn der Ordner bereits existiert, wird er geleert, bevor die Datei exportiert wird. Wenn sich auf der exportierten Seite kein Bild befindet, wird der Ordner gelöscht.
wk factur x	facturX	Nur für den PDF-Export. Wert: Objekt zur Konfiguration eines "Factur-X (ZUGFeRD)" PDF-Exports (siehe wk factur x objekt).
wk files	files	Nur für den PDF-Export. Wert: Collection von Objekten, von denen jedes eine Datei beschreibt, die in das endgültige Dokument eingebettet wird (siehe wk files collection). Diese Funktion wird nur in PDF/A-3-Dokumenten unterstützt: Wenn das Attribut wk files verwendet wird, wird automatisch die "PDF/A-3"-Version gesetzt (das Attribut wk pdfa version wird ignoriert). Im Falle eines Factur-X PDF-Exports (siehe unten) muss das erste Objekt der Collection die Factur-X xml-Datei enthalten.
wk google fonts tag	googleFontsTag	Nur für SVG-Export. Legt die Importregel für Google-Schriften im exportierten SVG fest. Mögliche Werte: false (Standard): Es wird keine Google-Fonts-Importregel hinzugefügt. wahr: Fügt die @import-Regel zur exportierten Datei hinzu. Nützlich, wenn Sie Schriftarten verwenden möchten, die unter Windows oder macOS nicht standardmäßig verfügbar sind. Hinweis: Diese Eigenschaft ist standardmäßig auf "false" gesetzt, da Google-Schriften, wenn sie aktiviert sind, die nativen Schriftarten überschreiben und native Schriftarten im Allgemeinen besser im Browser dargestellt werden.
wk HTML pretty print	htmlPrettyPrint	HTML Code wird formatiert, damit der Inhalt von Menschen leichter lesbar ist (Quelltextformatierung).
wk max picture DPI	maxPictureDPI	Zum Anpassen (Verkleinern) von Bildern auf die bevorzugte Auflösung. Für SVG Bilder unter Windows zur Rasterung. Standardwerte: 300 (für wk optimized for = wk print) 192 (für wk optimized for = wk screen) Maximal mögliche Werte: 1440
wk optimized for	optimizedFor	Definiert wie ein exportiertes Dokument entsprechend dem vorgesehenen Medium optimiert wird. Mögliche Werte: wk print (Standardwert für wk pdf) Bitmap Bilder werden mit der DPI geladen, definiert über wk max picture DPI oder mit 300 (Standardwert), und in PNG konvertiert, wenn Codec für den Exporttyp nicht unterstützt wird. Vektorbilder werden in PNG konvertiert, mit der DPI definiert durch wk max picture DPI oder mit 300 (nur Windows) Enthält ein Bild mehr als ein Format, wird das zum Drucken am besten geeignete Format verwendet (z.B. .tiff anstatt .jpg) wk screen (Standardwert für wk web page complete und wk mime html) Bitmap Bilder werden mit der DPI geladen, definert über wk max picture DPI oder mit 192 (Standardwert), und in JPEG (kompakte Bilder) oder PNG (transparente Bilder) konvertiert, wenn Codec für den Exporttyp nicht unterstützt wird. Vektorbilder werden in PNG konvertiert, mit der DPI definiert durch wk max picture DPI oder mit 192 (nur Windows) Enthält ein Bild mehr als ein Format, wird das Format zum Rendern des Bildschirms verwendet. Hinweis: Dokumente, die im Format wk docx exportiert werden, sind immer für wk print optimiert (die Option wk optimized for wird ignoriert).
wk page index	pageIndex	Nur für SVG-Export. Index der Seite, die in das SVG-Format exportiert werden soll (Standard ist 1). Der Seitenindex beginnt bei 1 für die erste Seite des Dokuments. Hinweis: Der Seitenindex ist unabhängig von der Seitennummerierung.
wk pdfa version	pdfaVersion	Exportiert PDF mit Konformität zu einer PDF/A-Version. Weitere Informationen zu den PDF/A-Eigenschaften und -Versionen finden Sie auf der PDF/A-Seite auf Wikipedia. Mögliche Werte: wk pdfa2: Exportiert nach Version "PDF/A-2" wk pdfa3: Exportiert nach Version "PDF/A-3" Hinweis: Unter macOS kann wk pdfa2 nach PDF/A-2 oder PDF/A-3 oder höher exportieren, je nach Plattformimplementierung. Außerdem bedeutet wk pdfa3 "exportiert mindestens nach PDF/A-3". Unter Windows wird die PDF-Ausgabedatei immer der gewünschten Konformität entsprechen.
wk recompute formulas	recomputeFormulas	Definiert, ob Formeln beim Export neu berechnet werden. Mögliche Werte: wahr - Standardwert. Alle Formeln werden neu berechnet falsch - Formeln nicht neu berechnen
wk visible background and anchored elements	visibleBackground	Zeigt Hintergrundbilder und Hintergrundfarbe an (sichtbarer Effekt nur im Modus Seite und Eingebunden). Mögliche Werte: True/False
wk visible empty images	visibleEmptyImages	Zeigt ein schwarzes Standardrechteck für Bilder an, die nicht geladen oder berechnet werden können (leere Bilder oder Bilder in einem nicht unterstützten Format). Mögliche Werte: Wahr/Falsch. Standardwert: True Wenn der Wert False ist, werden fehlende Bildelemente nicht angezeigt, auch wenn sie Rahmen, Breite, Höhe oder Hintergrund haben; dies kann sich auf das Seitenlayout für Inline-Bilder auswirken.
wk visible footers	visibleFooters	Zeigt die Fußteile an (sichtbarer Effekt nur im Modus Seite). Mögliche Werte: True/False
wk visible headers	visibleHeaders	Zeigt die Kopfteile an (sichtbarer Effekt nur im Modus Seite). Mögliche Werte: True/False
wk visible references	visibleReferences	Zeigt alle im Dokument eingefügte 4D Ausdrücke als Referenzen an. Mögliche Werte: True/False

Nachfolgende Tabelle gibt die verfügbare option je nach Export Format an:

	wk 4wp	wk docx	wk mime html	wk pdf	wk web page html 4D	wk svg
wk CID host domain name	-	-		-	-	-
wk HTML pretty print	(Standard: falsch)	-	(Standard: falsch)	(Standard: falsch)	(Standard: falsch)	(Standard: falsch)
wk max picture DPI	-	immer 300		(Standard: 300)	-	(Standard: 300)
wk optimized for	-	immer wk print	(Standard: wk screen)	immer wk print	-	(Standard: : wk print)
wk recompute formulas	-	(Standard: wahr)	(Standard: wahr)	(Standard: wahr)	-	(Standard: wahr)
wk visible background and anchored elements	-	(Standard: wahr)	immer wahr	(Standard: wahr)	-	(Standard: wahr)
wk visible footers	-	immer wahr	immer falsch	(Standard: wahr)	-	(Standard: wahr)
wk visible headers	-	immer wahr	immer falsch	(Standard: wahr)	-	(Standard: wahr)
wk visible empty images	-	(Standard: wahr)	(Standard: wahr)	(Standard: wahr)		(Standard: wahr)
wk visible references	-	-	-	(Standard: wahr)	-	(Standard: falsch)
wk page index	-	-	-	-	-	(Standard: 1)
wk pdfa version	-	-	-		-	-
wk factur x	-	-	-		-	-
wk files	-	-	-		-	-
wk embedded pictures	-	-	-	-	-	(Standard: wahr)
wk google fonts tag	-	-	-	-	-	(Standard: falsch)

Hinweis zur Kompatibilität: Zur Wahrung der Kompatibilität wird der Wert Lange Ganzzahl in Option noch unterstützt, wir empfehlen jedoch einen Parameter Objekt zu verwenden.

wk files collection

Mit der Eigenschaft wk files können Sie eine PDF-Datei mit Anhängen exportieren. Diese Eigenschaft muss eine Collection von Objekten enthalten, die die Dateien beschreiben, die in das endgültige Dokument eingebettet werden sollen. Jedes Objekt der Collection kann die folgenden Eigenschaften enthalten:

Eigenschaft	Typ	Beschreibung
name	Text	Dateiname. Optional, wenn die Eigenschaft file verwendet wird. In diesem Fall wird der Name standardmäßig aus dem Dateinamen abgeleitet. Obligatorisch, wenn die Eigenschaft data verwendet wird (außer für die erste Datei eines Factur-X-Exports, in diesem Fall lautet der Name für die Datei automatisch "factur-x.xml", siehe unten)
Beschreibung	Text	Optional. Falls nicht angegeben, ist der Standardwert für die erste Exportdatei nach Factur-X "Factur-X/ZUGFeRD Invoice", andernfalls leer.
mimeType	Text	Optional. Wenn ausgelassen, kann der Standardwert normalerweise aus der Dateierweiterung erraten werden; andernfalls wird "application/octet-stream" verwendet. Falls übergeben, stellen Sie sicher, dass Sie einen ISO-Mime-Typ verwenden, da die exportierte Datei sonst ungültig sein könnte.
data	Text oder BLOB	Obligatorisch, wenn die Eigenschaft file fehlt
file	4D.File object	Obligatorisch, wenn die Eigenschaft data fehlt, ansonsten ignoriert.
relationship	Text	Optional. Wenn nicht angegeben, ist der Standardwert "Daten". Mögliche Werte für die erste Factur-X-Datei: für die Profile BASIC, EN 16931 oder EXTENDED: "Alternative", "Quelle" oder "Daten" ("Alternative" nur für deutsche Rechnung) für die Profile MINIMUM und BASIC WL: Nur "Daten". für andere Profile: "Alternative", "Quelle" oder "Daten" (eventuell mit Einschränkungen je nach Land: siehe Profilspezifikation für weitere Informationen über andere Profile - für das Profil RECHNUNG ist z.B. nur "Alternative" erlaubt) für andere Dateien (außer Factur-X invoice xml file) : "Alternative", "Source", "Data", "Supplement" oder "Unspecified" jeder andere Wert erzeugt einen Fehler.

Wenn der option -Parameter auch eine wk factur x Eigenschaft enthält, dann muss das erste Element der Collection wk files die Factur-X (ZUGFeRD) invoice xml-Datei sein (siehe unten).

Hinweis: PDF-Anhänge werden nur von der PDF/A-3-Version unterstützt. Wenn Sie die Eigenschaft wk files übergeben, wird automatisch die Version "PDF/A-3" verwendet.

wk factur x objekt

Die Eigenschaft wk factur x ist ein Objekt, das bis zu zwei Eigenschaften enthalten kann:

Eigenschaft	Typ	Beschreibung
Profil	Text	Optional für Standardprofile, ansonsten obligatorisch. Wenn nicht angegeben, wird das Profil aus der angegebenen xml-Datei oder dem Text ermittelt (der ein Standardprofil verwenden muss). Falls übergeben, kann es sich um einen Nicht-Standard-Profilnamen handeln (für die Verwendung anderer Profile - zum Beispiel RECHNUNG). Hinweis: Standard-Profilnamen sind: MINIMUM, BASIC WL, BASIC, EN 16931 (auch bekannt als COMFORT, was ein Alias ist), EXTENDED.
version	Text	Optional. Standardwert ist "1.0"

Über Factur-X / ZUGFeRD PDF-Dokumente

Factur-X / ZUGFeRD ist ein europäischer Standard für hybride elektronische Rechnungen (PDF für User und XML-Daten für die Prozessautomatisierung). Für weitere Informationen lesen Sie bitte diesen Blogbeitrag.

Um einen "Factur-X"-PDF-Export auszulösen, übergeben Sie im Optionsparameter sowohl die Eigenschaften wk factur x als auch wk files (siehe Beispiel 5). In diesem Fall:

wird ein Factur-X (ZUGFeRD) PDF erzeugt,
wird das erste Element der Collection wk files als Factur-X xml-Datei verwendet,
Wenn die Eigenschaft wk files fehlt oder eine leere Collection enthält, oder wenn das erste Element keine XML-Datei ist, wird ein Fehler erzeugt.

Hinweis: Ein detailliertes Beispiel für die Implementierung des Factur-X / ZUGFeRD-Exports finden Sie in diesem HDI 4D-Projekt.

Beispiel 1

Den Inhalt des 4D Write Pro Objekts myArea in die beiden Formate HTML und PDF exportieren:

  // export HTML

 var $option : Object

 $option:=New object

 

 $option[wk recompute formulas]:=False

 $option[wk HTML pretty print]:=False

 $option[wk optimized for]:=wk print

 $option[wk max picture DPI]:=600 //Standardwert für Drucken überschreiben (300 DPI)

 

 WP EXPORT DOCUMENT(myArea;$path;wk web page complete;$option)

 

  //export PDF

 var $option : Object

 $option:=New object

 

 $option[wk visible headers]:=True

 $option[wk visible footers]:=True

 $option[wk visible background]:=True

 $option[wk max picture DPI]:=96 //Standardwert für Bildschirm überschreiben (192 DPI), um Größe des Dokuments zu beschränken.

 $option[wk optimized for]:=wk screen

 $option[wk recompute formulas]:=True

 

 WP EXPORT DOCUMENT(myArea;$path;wk pdf;$option)

Beispiel 2

Den Inhalt des 4D Write Pro Objekts myArea im .4wp Format exportieren:

 C_TEXT($path)

 C_LONGINT($docRef)

 

 Case of

    :(Form event code=On Clicked)

 

       $path:=Get 4D folder(Database folder)+"Export"+Folder separator

       $path:=Select document($path;".4wp";" title";File name entry)

 

       If($path#"")

          WP EXPORT DOCUMENT(myArea;document;wk 4wp;wk normal)

       End if

 End case

Beispiel 3

Um die zweite Seite des Dokuments als SVG zu exportieren und die Bilder aus dem Dokument zu exportieren:

 var $options : Object

 

 $options:=New object

 $options[wk embedded pictures]:=False

 $options[wk page index]:=2

 

 WP EXPORT DOCUMENT(WPArea;"my exported document";wk svg;$options)

Beispiel 4

Exporting a PDF document with PDF/A-2 conformance:

 var $options: Object:={}

 $options[wk visible empty images] :=False

 $options[wk pdfa version]:=wk pdfa2 // conformance "PDF/A-2"

 WP EXPORT DOCUMENT(wpDoc;"invoice.pdf";wk pdf;$options)

Beispiel 5

Beispiele für Factur-X PDF-Exporte:

  //BASIC (Standardprofil)

 var $options;$fileInfo : Object

 $options:={}

 $options[wk factur x]:={}

 $options[wk factur x].profile:="BASIC"

 $options[wk factur x].version:="1.0"

 

 $fileInfo:={}

 $fileInfo.file:=$file  //$file ist eine 4D.File mit einer .xml Datei als Ziel

 $options[wk files]:=[$fileInfo]

 

 WP EXPORT DOCUMENT(wpDoc;"facturX_basic.pdf";wk pdf;$options)

 

  //RECHNUNG Profil (Benutzerdefiniertes Profil)

 $options:={}

 $options[wk factur x]:={}

 $options[wk factur x].profile:="RECHNUNG"

 $options[wk factur x].version:="2.1" //letzte Version für RECHNUNG

 

 $fileInfo:={}

 $fileInfo.file:=$file  //$file ist eine 4D.File mit einer .xml Datei als Ziel

 $fileInfo.name:="rechnung.xml" //obligatorischer Dateiname in PDF für RECHNUNG

 $fileInfo.relationship:="Alternative" //obligatorisch für Deutschland

 $fileInfo.description:="ZUGFeRD Rechnung"

 $options[wk files]:=[$fileInfo]

 

 WP EXPORT DOCUMENT(wpDoc;"facturX_rechnung.pdf";wk pdf;$options)

Siehe auch

4D QPDF (Component) - PDF Get attachments
Blog post - 4D Write Pro: Electronic invoice generation
Blog post - 4D Write Pro: Export to PDF with enclosures
Exportieren in die Formate HTML und MIME HTML
Exporting to SVG format
Import und Export im Format .docx
WP EXPORT VARIABLE